globals [
  ;; general gaslab stuff
  losses              ;; number of particles that have escaped the atmosphere
  clock vsplit vclock ;; clock variables
  initspeed           ;; initspeed of atm-particles. balloon-particle initspeed
                      ;; is computed from this.
  gravity*             ;; gravitational constant

  ;; balloon quantities
  balloon-patches             ;; agentset representing the balloon
  balloon-radius              ;; size of the balloon. strange to call it radius
  balloon-pos-y balloon-pos-x ;; position of ballon
  atm-top atm-bottom          ;; forces from the atmosphere on the ballon
  balloon-top balloon-bottom  ;; forces from within the balloon
  history-length              ;; how much history to keep
  balloon-top-history         ;; histories of forces
  balloon-bottom-history
  atm-top-history
  atm-bottom-history
]

breeds [
  atm-particles     ;; molecules in the atmosphere
  balloon-particles ;; molecules in the balloon
]

turtles-own
[
  speed mass energy                     ;; turtle info
  v1t v1l tmp-turtle                    ;; collision info (turtle 1)
  heading2 mass2 speed2 v2t v2l turtle2 ;; collision info (turtle 2)
  theta                                 ;; collision info (both turtles)
]

to setup
  ca
  setup-variables
  
  set-default-shape atm-particles "circle"
  set-default-shape balloon-particles "circle-small"

  ;; draw the surface at the bottom of the screen
  ask patches with [pycor = (- screen-edge-y)] [ set pcolor yellow ]

  draw-balloon

  ;; create the atmospheric molecules
  create-custom-atm-particles particles-in-atmosphere
  [
    set speed initspeed
    set mass atmospheric-particle-mass
    position-atm-particles
    rt random-int-or-float 360
    recolor
  ]
  
  ;; create the balloon molecules
  create-custom-balloon-particles particles-in-balloon
  [
    set speed initspeed * sqrt (atmospheric-particle-mass / inside-balloon-particle-mass)
    set mass inside-balloon-particle-mass
    position-balloon-particles
    rt random-int-or-float 360
    if (inside-balloon-particle-mass = 44)
      [ set size 2.5 ]
    recolor
  ]
    
  update-variables
  ;setup-plots
  ;do-plotting
  display
end

;; sets up all relevant global variables
to setup-variables
  set clock 0
  set vclock 0
  set initspeed 5.0
  set gravity* gravity
  set balloon-radius 15
  set balloon-pos-y (10 - screen-edge-y) + balloon-radius
  set balloon-pos-x 0
  set history-length 50
  set balloon-top-history [ 0 ]
  set balloon-bottom-history [ 0 ]
  set atm-top-history [ 0 ]
  set atm-bottom-history [ 0 ]
end

to go
  no-display
  reset-variables
  ask atm-particles [ bounce ]
  ask atm-particles [ move ]
  ask balloon-particles [ bounce ]
  ask balloon-particles [ move ]
  move-balloon

  ;; this will stop the model if the balloon hits the ceiling.
  if (round (balloon-pos-y + balloon-radius)) >= screen-edge-y
  [
    display
    stop
  ]

  ;create-trace
  clock-tick
  display
end

;; records relevant quantities in history lists and resets variables used
;; during the go loop
to reset-variables
  ifelse length balloon-top-history < history-length
  [
    set balloon-top-history fput balloon-top balloon-top-history
  ]
  [
    set balloon-top-history fput balloon-top (but-last balloon-top-history)
  ]
  ifelse length balloon-bottom-history < history-length
  [
    set balloon-bottom-history fput balloon-bottom balloon-bottom-history
  ]
  [
    set balloon-bottom-history fput balloon-bottom
      (but-last balloon-bottom-history)
  ]
  ifelse length atm-top-history < history-length
  [
    set atm-top-history fput atm-top atm-top-history
  ]
  [
    set atm-top-history fput atm-top (but-last atm-top-history)
  ]
  ifelse length atm-bottom-history < history-length
  [
    set atm-bottom-history fput atm-bottom atm-bottom-history
  ]
  [
    set atm-bottom-history fput atm-bottom (but-last atm-bottom-history)
  ]
  set atm-top 0
  set atm-bottom 0
  set balloon-top 0
  set balloon-bottom 0
end

;; moves the balloon, if necessary.
to move-balloon
  ;; only move the balloon down if it's not already at the bottom...
  if ((balloon-bottom + atm-top) > (balloon-top + atm-bottom))
    and not ((round (balloon-pos-y - balloon-radius)) <= (1 - screen-edge-y))
  [
    balloon-down 1
  ]
  if ((balloon-bottom + atm-top) < (balloon-top + atm-bottom))
  [
    balloon-up 1
  ]
end

;; performs a vclock tick, taking appropriate actions if one entire clock
;; tick has elapsed.
to clock-tick
  set vclock (vclock + 1)
  if vclock = vsplit
  [
    set clock (clock + 1)
    set vclock 0
    update-variables
    ;do-plotting 
  ]
end

;; moves an atmospheric particle to a random position
;; the add/sub 1's are to make sure the particles don't get caught within the
;; balloon/ground walls
to position-atm-particles  ;; turtle procedure
  locals [ new-x new-y done ]
  set done false
  while [ not done ]
  [
    set new-x (random-int-or-float (2 * screen-edge-x)) - screen-edge-x
    set new-y (random-int-or-float (screen-edge-y - 1)) - screen-edge-y + 1
    if not in-balloon new-x new-y
    [
      set done true
    ]
  ]
  setxy new-x new-y
end

to-report in-balloon [x y]
  if x > balloon-pos-x - balloon-radius - 1 and x < balloon-pos-x + balloon-radius + 1
    and y > balloon-pos-y - balloon-radius - 1 and y < balloon-pos-y + balloon-radius + 1
  [
    report true
  ]
  report false
end

;; moves a balloon particle to a random position
to position-balloon-particles  ;; turtle procedure
  setxy ((balloon-pos-x - balloon-radius + 1) + random-int-or-float (2 * balloon-radius - 1))
        ((balloon-pos-y - balloon-radius + 1) + random-int-or-float (2 * balloon-radius - 1))
end

to recolor  ;; turtle procedure
    ifelse speed < (0.5 * initspeed)
    [ set color blue ]
    [
      ifelse speed > (1.5 * initspeed)
      [
        set color red
      ]
      [
        set color green
      ]
    ]
end

to update-variables
  ask turtles
    [ set energy (0.5 * speed * speed * mass) ]
  
  ifelse any? turtles
    [ set vsplit ceiling max values-from turtles [speed + gravity] ]
    [ set vsplit initspeed ]

  set losses (particles-in-atmosphere - count atm-particles)
end


to factor-gravity ;; turtle procedure
  locals [ vx vy ]
  set vx (sin heading * speed)
  set vy (cos heading * speed) - gravity / vsplit
  set speed sqrt ((vy * vy) + (vx * vx))
  recolor
  set heading atan vx vy
end

to move
  ;; In other GasLab models, we use "jump speed / vsplit" to move the
  ;; turtle the right distance along its current heading.  In this
  ;; model, though, the molecules are affected by gravity as well, so we
  ;; need to offset the turtle vertically by an additional amount.  The
  ;; easiest way to do this is to use "setxy" instead of "jump".
  ;; Trigonometry tells us that "jump speed / vsplit" is equivalent to:
  ;;   setxy (xcor + sin heading * speed / vsplit)
  ;;         (ycor + cos heading * speed / vsplit)
  ;; so to take gravity into account we just need to alter ycor
  ;; by an additional amount given by the classical physics equation:
  ;;   y(t) = 0.5*a*t^2 + v*t + y(t-1)
  ;; but taking vsplit into account, since vsplit is a subdivider of t.
  setxy (xcor + sin heading * speed / vsplit)
        (ycor + cos heading * speed / vsplit - gravity / (2 * vsplit * vsplit))
  factor-gravity
  if (pycor = screen-edge-y) [ die ]
  check-for-collision
end

to check-for-collision
  if count other-turtles-here = 1
    [
      set tmp-turtle random-one-of other-turtles-here
      if ((who > who-of tmp-turtle) and (turtle2 != tmp-turtle)) [ collide ]
    ]
end

to bounce
  locals [ new-px new-py ]

  ;; if we're not about to hit the ground (yellow) or balloon (turquoise),
  ;; we don't need to do any more checks
  if (pcolor-of patch-at dx dy != yellow)  and
    (pcolor-of patch-at dx dy != turquoise)
  [
    stop
  ]

  ;; get the coordinates of the patch we'll be on if we go forward 1
  set new-px round (xcor + dx)
  set new-py round (ycor + dy)

  ;; if particles hit the 'ground'
  if (abs new-py = screen-edge-y)
    [ set heading (180 - heading) ]
    
  ;; if particles hit the sides of the balloon
  if ((round abs (balloon-pos-x - new-px)) = balloon-radius)
    [ set heading (- heading) ]

  ;; if particles hit the top or bottom of balloon
  if (new-py = (round (balloon-pos-y + balloon-radius)))
  [
    set heading (180 - heading) 
    if (ycor > new-py) 
    [
      set atm-top atm-top + abs (cos heading * (10 * mass) * speed)
    ]
    ;; if ycor > new-py, particle is bouncing from inside balloon
    if (ycor < new-py)
    [
      set balloon-top balloon-top + abs (cos heading * (10 * mass) * speed)
    ]
  ]
  if (new-py = (round (balloon-pos-y - balloon-radius)))
  [
    set heading (180 - heading)
    if (ycor < new-py)
    [
      set atm-bottom atm-bottom + abs (cos heading * (10 * mass) * speed)
    ]
    if (ycor > new-py)
    [
      set balloon-bottom
        balloon-bottom + abs (cos heading * (10 * mass) * speed)
    ]      
  ]
end

to collide
  get-turtle2-info
  calculate-velocity-components
  set-new-speed-and-headings
end

to get-turtle2-info
  set turtle2 tmp-turtle
  set mass2 mass-of turtle2
  set speed2 speed-of turtle2
  set heading2 heading-of turtle2
end

to calculate-velocity-components
  locals [ vcm ]
  set theta (random-int-or-float 360)
  set v1l (speed * sin (theta - heading))
  set v1t (speed * cos (theta - heading))
  set v2l (speed2 * sin (theta - heading2))
  set v2t (speed2 * cos (theta - heading2))
  set vcm (((mass * v1t) + (mass2 * v2t)) / (mass + mass2))
  set v1t (vcm + vcm - v1t)
  set v2t (vcm + vcm - v2t)
end

to set-new-speed-and-headings  ;;turtle procedure
  set speed sqrt ((v1t * v1t) + (v1l * v1l))
  set heading (theta - (atan v1l v1t)) 

  set speed-of turtle2 sqrt ((v2t * v2t) + (v2l * v2l))
  set heading-of turtle2 (theta - (atan v2l v2t))

  recolor
  ask turtle2 [ recolor ]
end

to draw-balloon
  ;; here we recalculate the patches, since the balloon might've moved.
  set balloon-patches calc-balloon-patches
  ask balloon-patches [ set pcolor turquoise ]
end

to undraw-balloon
  ask balloon-patches [ set pcolor black ]
end

to-report calc-balloon-patches
  report patches with
    [((round abs (balloon-pos-x - pxcor) = balloon-radius)
     and (round abs (balloon-pos-y - pycor) <= balloon-radius))
    or ((round abs (balloon-pos-y - pycor) = balloon-radius)
     and (round abs (balloon-pos-x - pxcor) <= balloon-radius))]
end

to bounce-up
  setxy xcor (ycor + 2)
end

to bounce-down
  setxy xcor (ycor - 2)
end

to balloon-up [dist]
  locals [new-balloon-pos-y redraw]
  without-interruption
  [
    if (dist > 0)
    [ 
      ifelse ((balloon-pos-y + dist) < screen-edge-y - 1)
        [ set new-balloon-pos-y (balloon-pos-y + dist) ]
        [ set new-balloon-pos-y (screen-edge-y - 1) ]
      set redraw (round new-balloon-pos-y) != (round balloon-pos-y)
      if redraw [ undraw-balloon ]
      set balloon-pos-y new-balloon-pos-y
      if redraw [ draw-balloon ]
      ask turtles with
        [((round abs (balloon-pos-y - pycor)) = balloon-radius)
          and ((round abs (balloon-pos-x - pxcor)) <= balloon-radius)]
      [
        bounce-up
      ]
    ]
  ]
end

to balloon-down [dist]
  locals [new-balloon-pos-y redraw]
  without-interruption
  [
    if (dist > 0)
    [ 
      ifelse (balloon-pos-y - dist) > (2 - screen-size-y)
        [ set new-balloon-pos-y (balloon-pos-y - dist) ]
        [ set new-balloon-pos-y (3 - screen-size-y) ]
      set redraw (round new-balloon-pos-y) != (round balloon-pos-y)
      if redraw [ undraw-balloon ]
      set balloon-pos-y new-balloon-pos-y
      if redraw [ draw-balloon ]
      ask turtles with
        [((round abs (balloon-pos-y - pycor)) = balloon-radius)
          and ((round abs (balloon-pos-x - pxcor)) <= balloon-radius)]
      [
        bounce-down
      ]
    ]
  ]
end

;; computes the user-visible balloon height
to-report balloon-height
  report balloon-pos-y + screen-edge-y - balloon-radius - 1
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; PLOTTING CODE                                                          ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to setup-plots
  set-current-plot "Balloon height"
  ;set-current-plot "Forces on balloon walls"
  ;draw-horiz-line "zero" 0
end

to do-plotting
  plot-balloon-height
  plot-balloon-forces
  ;plot-balloon-net-forces
end

to plot-balloon-height
  set-current-plot "Balloon Height"
  set-current-plot-pen "height"
  plot balloon-height
end

to plot-balloon-forces
  set-current-plot "Forces on Balloon"
  set-current-plot-pen "upwards"
  plot (mean balloon-top-history + mean atm-bottom-history)
  set-current-plot-pen "downwards"
  plot (mean balloon-bottom-history + mean atm-top-history)
end

to plot-balloon-net-forces
  set-current-plot "Forces on balloon walls"
  set-current-plot-pen "top-wall"
  plot (mean balloon-top-history - mean atm-top-history)
  set-current-plot-pen "bottom-wall"
  plot (mean atm-bottom-history - mean balloon-bottom-history)
end
 
to draw-horiz-line [name yval]
  create-temporary-plot-pen name
  plotxy plot-x-min yval
  plotxy plot-x-max yval
  plot-pen-up
end


; *** NetLogo Model Copyright Notice ***
;
; This activity and associated models and materials were created as part of the project:
; MODELING ACROSS THE CURRICULUM.  The project gratefully acknowledges the support of the 
; National Science Foundation, National Institute of Health and the Department of Education 
; (IERI program) -- grant number REC # 0115699. Additional support was provided through the 
; project: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS 
; -- NSF (REPP program) -- grant number REC #9814682.
;
; Copyright 2003 by Uri Wilensky.  Updated 2003.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2003).  NetLogo Chem Balloon 1 model.
; http://ccl.northwestern.edu/netlogo/models/ChemBalloon1.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/ChemBalloon1
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
234
22
566
375
80
80
2.0
0
10
1
1
1

CC-WINDOW
259
380
558
500
Command Center

BUTTON
16
69
83
102
NIL
setup
NIL
1
T
OBSERVER
T

BUTTON
83
69
146
102
NIL
go
T
1
T
OBSERVER
T

SLIDER
5
251
210
284
particles-in-atmosphere
particles-in-atmosphere
0
500
300
1
1
NIL

SLIDER
5
283
223
316
atmospheric-particle-mass
atmospheric-particle-mass
4
28
28
4
1
amu

SLIDER
5
390
227
423
inside-balloon-particle-mass
inside-balloon-particle-mass
4
28
28
4
1
amu

TEXTBOX
39
465
215
523
Helium: 4 amu\nNitrogen: 28 amu

MONITOR
21
127
78
176
NIL
clock
0
1

SLIDER
5
357
180
390
particles-in-balloon
particles-in-balloon
0
40
15
1
1
NIL

SLIDER
10
196
182
229
gravity
gravity
0
1
0.5
0.1
1
NIL

@#$#@#$#@

WHAT IS IT?
-----------
This model is part of the GasLab collection of models.  See GasLab Gas in a Box for an introduction to the GasLab collection.

It tends to be taken for granted a lot that balloons filled with Helium gas float upward.  This model tries to explain what are some of the factors that cause this movement through the simulation the effect of gravity on gas molecules?  These factors include:  density, pressure, mass, number of particles, collisions

As with wood floating in water, the phenomenon is a result of differences in the density of the material in relation to the medium it is in.  Within the atmosphere, as particles are moving around, there is also a force of gravity that is acting upon each particle.  In looking at a free-body diagram, there is only one external factor affecting particle movement, mass * gravity going downward.  This allows for a density dispersion of particles within the atmosphere with the density increasing the closer the particle is to the earth.  The dispersion of the gas within the balloon causes the balloon's movement.  Because a gas that is lighter than the atmospheric particles surrounding it will tend to be pulled down less by gravity than a heavier particle, the particles contained within the balloon will be dispersed differently than the atmospheric dispersion -- overall, they will be higher and moving the balloon with them.  Similarly, if a balloon is filled with a heavier gas, say carbon dioxide, the different dispersion of gases within the balloon will cause it to sink downward.  If the balloon reaches a density of gas that is the same as the density at a certain level within the atmospheric, the balloon will hover at that point.  
This is the macroscopic cause of the balloon?s behavior, the law of buoyancy.  

This is where pressure comes into the picture.  First, because the 'balloon' is modeled after an aluminum balloon where volume is fixed, increased pressure within the balloon itself will not directly have any effect on the balloon's movement.  However, increasing the pressure without increasing the volume will transform that energy into heat energy that they absorb to become excited.  This causes the particles to move faster and collide with the balloon walls more often and with greater force.  As with density, a balloon will tend to move to where the force of pressure is equal.  Therefore, when less dense gases exert the same amount of force as more dense gases, this can cause balloons to rise.

Microscopically, the balloon?s behavior is decided ultimately by all the particles that are bouncing off its walls.  Each particle that bounces off a balloon wall transfers its momentum to the balloon.  Particles all around the balloon and inside the balloon are all transferring momentum to its walls.  When these forces all cancel, the balloon will hover.  However, when these forces are not equal, they do not cancel, and the balloon will move in whatever direction the force is pushing it most.  The strength of these forces are related to density and pressure in that the greater the density and pressure, the more momentum is transferred upon collision.  Because of the density gradient outside the balloon as well as inside, the balloon will ultimately settle where the two density gradients are even. 

Everything that affects density affects the macroscopic behavior of the balloon.  Number of particles both inside the balloon and just within the atmosphere, the mass of the particles, even size (the larger the particle, the more volume it takes up) all affect the balloon?s overall movement.


HOW IT WORKS
------------
For the basics of how all GasLab models work, see GasLab Gas in a Box.

In this model, there are several objects on the screen at once.  There is a ?planet?, represented by a yellow line at the bottom of the screen, a ?balloon?, represented by a turquoise square in the middle of the screen, gaseous ?atmosphere? that is placed above the surface of the planet and surrounds the balloon, and a different gas from the atmosphere that is contained within the balloon.  Each of the gas particles, regardless of whether they are inside our outside the balloon, are given additional velocity downward during each tick, as it would get in a gravity field.  The molecules then collide with each other, and bounce off the ?ground? and balloon walls.  If the impacts of the molecules bouncing off the top and bottom walls of the balloon are not equal, based on which impact is stronger, the balloon will either rise or sink.  Some molecules disappear if they reach the top of the screen, as if they had escaped from the planet?s gravitational field.

The exact way two particles collide is as follows: 
1. Two turtles "collide" when they find themselves on the same patch. 
2. A random axis is chosen, as if they were two billiard balls that hit and this axis was the line connecting their centers. 
3. They exchange momentum and energy along that axis, according to the conservation of momentum and energy. This calculation is done in the center mass system. 
4. Each turtle is assigned its new speed, energy and heading. 
5. If a turtle (balloon-particle or atmospheric-particle) finds itself on or very close to a balloon wall, it "bounces"



HOW TO USE IT
-------------
Buttons:
- SETUP: sets the initial conditions
- GO: runs the model simulation

Sliders:
- GRAVITY: the strength of the gravitational acceleration 
- PARTICLES-IN-ATM: number of particles in the atmosphere (outside the balloon)
- ATMOSPHERIC-MASS: initial mass of the particles in the atmosphere
- PARTICLES-IN-BALLOON: number of particles inside the balloon
- MASS-INSIDE-BALLOON: mass of the particles inside the balloon

Switch:
- TRACE?: will trace the path of one atmospheric particle
(an artifact from the atmoshpere model, may or may not be useful)

Monitors:
- LOST-ATM-PARTICLES: counts the number of atmospheric particles lost, forever floating upward
- AVG-SPEED: average speed of the molecules
- CLOCK: number of ticks that have passed
Plots:
- HEIGHT: the height of the balloon over time
(the height is measured from the bottom of the balloon, the graph is scaled to reflect that)


THINGS TO NOTICE
----------------
Watch the balloon?s movement stabilize as the model runs.  What?s causing these fluctuations?

Look at the distribution of molecules inside the balloon versus outside.  Are they related?  And if so, how?

Does this model ever reach an equilibrium?

How does the model run differently for the different types of particles filling the balloon?


THINGS TO TRY
-------------
Determine what settings to change to cause the balloon to float upward or downward.  

Keep everything the same and just add more particles to the balloon and run the model.  Then take most of them out and run the model.  Do the same with the atmosphere.

Try plotting the density within the balloon versus the density of the atmosphere.


EXTENDING THE MODEL
-------------------
Introduce gravity units (relate to physics concept of acceleration), research gravity to accurately represent different planets.

Incorporate air into the ?mass-inside-balloon? slider.  Predict how the plot of ?Balloon Height? will change over time with this new gas inside the balloon.
 
Give the balloon horizontal movement as well as vertical, check to see that movement should stabilize over time because density dispersion horizontally does not change.

Add water as a new medium for the balloon to be placed in.  What will the effect be on a balloon filled with helium?  With carbon dioxide?

Allow the balloon?s size to change and see the effect of the changing volume, and therefore changing density, on the balloon?s ability to float.


NETLOGO FEATURES
----------------
This model makes use of the 'turtle-shapes' and 'turtle-size' features.  However, it is only for aesthetic purposes that the particles are round and that their mass correlates with their visual size.  Turning these features off within the graphics screen speeds the model up very noticeably.


RELATED MODELS
--------------
Connected Chemistry curriculum gaslab models
specifically - Atmosphere


CREDITS AND REFERENCES
----------------------
To refer to this model in academic publications, please use: Wilensky, U. (2002). NetLogo (model name here) model. http://ccl.northwestern.edu/netlogo/models/ChemBalloon1. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL. 

In other publications, please use: Copyright 2002 by Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/ChemBalloon1 for terms of use.



@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

balloon
false
0
Circle -7566196 false true 41 14 215
Polygon -7566196 false true 135 230 162 228 170 254 126 254

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

circle-big
true
0
Circle -7566196 true true 2 2 295

circle-small
true
0
Circle -7566196 true true 88 86 125

fast-big
true
1
Circle -65536 true true 60 60 178

fast-small
true
1
Circle -65536 true true 103 103 92

medium-big
true
5
Circle -11352576 true true 60 60 179

medium-small
true
5
Circle -11352576 true true 103 103 92

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

slow-big
true
10
Circle -16776961 true true 58 57 182

slow-small
true
10
Circle -16776961 true true 104 103 94

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0beta5
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@