patches-own [ temp ]            ;; temperature of the patches or water molecules                   
globals     [ total-added       ;; total amount added of turtles (NH4NO3) added to the patches (water)
              total-dissolved   ;; total amoung of NH4NO3 that dissolved in water
              was-sped-up?      ;; whether the model has been running at increased speed
              clock]            ;; counts the amount of time it takes for the NH4NO3 to dissolve in the water

;; Procedure to set up all the initial variables.  The total-added, total-dissolved and clock are all set 
;; at zero.  The temperature of the patches (water) is set at 20 C (room temperature).
to setup
  ca
  set total-added 0
  set total-dissolved 0
  set clock 0
  set was-sped-up? false
  ask patches
   [set temp 20]
  recolor
  do-plotting
  display  ;; make sure that we can see the graphics window
end

;; Procedure to add ammonium nitrate to the water.  The turtles are given their characteristics:
;; shape, color, direction and movement.
to add-ammonium-nitrate
  set total-added total-added + amount
  ;; each turtle is a 0.01mol crystal of Ammonium Nitrate
  ;; 0.01mol NH4NO3 has a mass of 0.8g
  cct amount / .8
  [
    set shape "box"
    set color green
    rt random-float 360
    fd random-float 5
  ]
end

;; Procedure that makes the model run. Turtles (NH4NO3) wander around on the patches and if the temp
;; of the patch is greater than zero, then the turtles will dissolve into that patch or water molecule.
;; If the patch the turtle is on is less than zero, the turtle cannot dissolve with that patch or 
;; water molecule.  (A water molecule with a temp less than zero is in the form of ice.)  
;; The turtle then tries to find the closest patch that has a temp more than zero.  After the dissolution,
;; the patch will change it's color to represent the change in temperature.
to go
  ;; the speed slider is the speed of the graphics window updating, not the speed of the reaction.  As the number 
  ;; on the speed slider increases, so does the amount of time between graphics window updates.  
  ifelse speed > 1
  [
    every speed - 1
    [
      set was-sped-up? true
      display
      no-display
    ]
  ]
  [
    if was-sped-up?
    [
      set was-sped-up? false
      display
    ]
  ] 
   
  ask turtles
  [
    ifelse temp > 0
    [
      fd temp / 100
      rt random-float 20
      lt random-float 20
      ;; dissolution is somewhat easier in warmer water
      if random floor (100 - temp) = 0
      [ dissolve ]
    ]
    [
      ;; simulate the pushing of the solute out of the ice when it freezes
      set heading uphill temp
      fd 1
    ]
  ]
  diffuse temp 0.5
  recolor
  if total-added > 0
  [
    do-plotting 
    set clock clock + 1
  ]
end

;; When this button is pressed, it stirs the solution by asking the turtles
;; to set their heading 270 and move towards the center of the screen while 
;; moving forward in the direction the turtle is pointing 5 steps.  This will 
;; create a swirl affect in the graphics window. 
to stir
  ask turtles
  [
    set heading -90 + towardsxy 0 0
    fd 5
  ]
end

;; Procedure to recolor after the patch has dissolved a turtle.
;; If the temp of the patch is greater than zero then a color change will occur.
;; If the temp of the patch is less than zero then change color to white.
to recolor
  ask patches
  [
    ifelse temp > 0
    [ set pcolor scale-color blue temp 30 -10 ]
    [ set pcolor 8 ]
  ]
end

;; To dissolve, lower the patch temp to reflect that a turtle dissolved with it.  Then 
;; recalculate the total-dissolved value shown on the monitor.  Turtle will die or dissappear.
to dissolve  ;; turtle procedure
  set temp temp - 33.2
  set total-dissolved total-dissolved + .8
  die
end

;; Plotting procedures
to do-plotting
  set-current-plot "Temp vs. Time"
  set-current-plot-pen "x-axis"
  plot 0
  set-current-plot-pen "Temp"
  plot mean values-from patches [temp]
  set-current-plot "Dissolution vs. Time"
  set-current-plot-pen "added"
  plot total-added
  set-current-plot-pen "dissolved"
  plot total-dissolved
end


; *** NetLogo Model Copyright Notice ***
;
; This activity and associated models and materials were created as part of the project:
; MODELING ACROSS THE CURRICULUM.  The project gratefully acknowledges the support of the 
; National Science Foundation, National Institute of Health and the Department of Education 
; (IERI program) -- grant number REC # 0115699. Additional support was provided through the 
; project: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS 
; -- NSF (REPP program) -- grant number REC #9814682.
;
; Copyright 2003 by Uri Wilensky.  Updated 2003.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2003).  NetLogo Chem Cold Pack model.
; http://ccl.northwestern.edu/netlogo/models/ChemColdPack.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/ChemColdPack
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
331
10
685
385
21
21
8.0
1
10
1
1
1

CC-WINDOW
331
387
685
507
Command Center

BUTTON
5
10
74
43
NIL
Setup
NIL
1
T
OBSERVER
T

BUTTON
79
10
142
43
NIL
Go
T
1
T
OBSERVER
T

SLIDER
5
50
210
83
amount
amount
1
1000
642.5
0.5
1
g

BUTTON
5
83
210
116
Add Ammonium Nitrate
add-ammonium-nitrate
NIL
1
T
OBSERVER
T

MONITOR
176
143
304
192
Avg Temp (C)
mean values-from patches [temp]
1
1

MONITOR
10
145
134
194
Total Added (g)
total-added
1
1

MONITOR
10
197
134
246
Total Dissolved (g)
total-dissolved
1
1

PLOT
689
10
969
196
Temp vs. Time
time
temp
0.0
100.0
-5.0
20.0
true
true
PENS
"Temp" 1.0 0 -65536 true
"x-axis" 1.0 0 -7566196 true

PLOT
689
200
969
385
Dissolution vs. Time
time
amount
0.0
100.0
0.0
100.0
true
true
PENS
"added" 1.0 0 -8716033 true
"dissolved" 1.0 0 -16745473 true

MONITOR
177
195
303
244
Molarity (mol/L)
total-dissolved / 80.0
1
1

BUTTON
147
10
210
43
NIL
Stir
T
1
T
OBSERVER
T

MONITOR
223
10
327
59
Clock
clock
0
1

SLIDER
13
280
185
313
speed
speed
1
5
3.3
0.1
1
NIL

TEXTBOX
15
323
305
397
The increase in speed, decreases the number of times the graphics window displays the reaction.  The reaction is still occurring and data can be seen in the plots and monitors.

@#$#@#$#@
Connected Chemistry Curriculum is currently under development, for more information please refer to http://ccl.northwestern.edu/curriculum/chemistry/

WHAT IS IT?
-----------
This model simulates an endothermic reaction between ammonium nitrate (NH4NO3) and water (H20).  When these two substances are combined two changes happen 1) a change in the solution's temperature and 2) the dissolution of the NH4NO3.  The NH4NO3 is water-soluble and therefore dissolves into the water as seen in the equation below.

|       NH4NO3 (s) + energy + H20 -----> NH4 (aq) + NO3 (aq)  

As the NH4NO3 is dissolving in the water, it requires energy to dissociate into NH4 and NO3.  The energy comes from the kinetic energy of the water molecules.  As the kinetic energy is absorbed into the dissociation reaction, the overall energy of the water decreases corresponding to a decrease in temperature.   The more NH4NO3 you place into the reaction, assuming the water amount is fixed, the colder the solution will become.  This is type of reaction is called an endothermic reaction. 

The Chem Cold Pack model is the first model in the Connected Chemistry High School Curriculum.  In this model, students will be exploring how an endothermic reaction occurs and how it is used in household products like first aid cold packs or drink and food cold packs.  As part of this curriculum students will be looking at a variety of models in trying to learn Kinetic Molecular Theory and Gas Laws.  This model and the first chapter are priming the students to look closely at computer models and compare them to other types of models such as mental models and 3-D models.  Both the Chem Cold Pack model and activity ask the students to switch between these two representations to figure out how a cold pack works.  Then after they have created a mental model of the cold pack mechanism, they will build their own cold pack to test out their theory.   After students have a good understanding of models, they will then move into the next two chapters that use models to help students understand the Kinetic Molecular Theory and Gas Laws.  Other models in this curriculum include: Chem Sequence, Chem Presssure 1 and 2, Chem Volume 1 and 2, and Chem Heat Box. 


HOW IT WORKS
------------
Turtles represent the ammonium nitrate and are seen as green boxes.  The patches represent water and their initial color is deep blue which signifies room temperature.  When the simulation starts the graphics window turns the deep blue color.  As ammonium nitrate is added, the color of the water starts to lighten.  The ammonium nitrate (turtles) is dissolving in the water (patches) and decreasing the temperature.

1. Turtles are introduced from the middle of the graphics window.  If large amount of turtles are introduced they are standing on top of each other.

2. When turtles encounter a patch, the turtle checks to see it's temp value.

3. If the temp value of the patch is greater than zero, the turtle will dissolve with the patch and die.  This interaction results in lowering the patches temperature and changing its color.

4. If the temp value of the patch is less than zero, the turtle will not dissolve with the patch.  The patch has turned solid (ice) and cannot dissolve anything.

5.  The un-dissolved turtle will then seek a patch with a temp value greater than zero.
 
The simulation continues going until all the turtles have dissolved or until all the patches have become a solid.

Model Specs:

1mol NH4NO3 = 80g
1mol H20 = 18.03g = 18.03mL
75.312J/mol = 4.184J/g = 1cal = Heat Capacity of Water(J/g)
1kJ = 239cal
-25kJ/mol = heat of dissolution of NH4NO3
#patches = 1849
0.1mol H20/patch
184.9mol H20 = ~1L H20

Molar Heat Capacity(J/mol) = Specific Heat Capacity(J/g) * molar mass(g/mol)

1mol NH4NO3 dissolving lowers the temperature of 1mol H20 by 332K
0.01mol NH4NO3 = 0.8g
0.01mol NH4NO3 dissolving lowers the temperature of 0.1mol H20 by 33.2K
  

HOW TO USE IT
-------------
To start the model, press SETUP then GO.  You will notice the graphics window changes from black to blue.  The blue represents the water.  When you press the ADD-AMMONIUM-NITRATE button, you will see green turtles appear.  These turtles represent the solute in this solution.  To increase the surface area of the solute and the solvent, use the STIR button.  When this button is pressed it will continuously stir the solution until the button is un-pressed. 

Buttons:
  SETUP - Sets up all the variables prior to running the simulation.
  GO - Runs the simulation.
  STIR - Stirs the solution continuously until the button is un-pressed.
  ADD AMMONIUM NITRATE - Added the amount of ammonium nitrate displayed on the amount slider.

Sliders:
  AMOUNT - Determines the amount of ammonium nitrate that will be added to the solution.
  SPEED - Regulates how many times the graphics window gets updated. The number is the amount of time between updates.  The lower the number the less time between updates, the slower the model runs.  The higher the number, the more time between updates, the faster the model runs.

Monitors:
  CLOCK - Displays how many times the procedure has been run.
  TOTAL ADDED (g) - Displays the total number of grams of ammonium nitrate that has been added.
  TOTAL DISSOLVED (g) - Displays the total number of grams of ammonium nitrate that has been dissolved.
  AVG TEMP (C) - Displays the average temperature of the solution.
  MOLARITY (mole/L) - Displays the molarity of the solution.

Plots:
  DISSOLUTION VS. TIME - Plots the amount of dissolved ammonium nitrate over time.
  TEMP VS TIME - Plots the amount of temperature over time.


THINGS TO NOTICE
----------------
1) As you run the model, you may notice the turtles that are on the edges of the graphics window leave the screen.  They wrap from one side to the other side of the screen.

2) Use the STIR button to move the NH4NO3 out from the center.  If a large number of NH4NO3 is introduced it will begin making ice patches at the corners then pushing the NH4NO3 towards the middle.

3) The clock will start when the first "spurt" of NH4NO3 is added to the water.

4) When the model has hit the saturation point, the un-dissolved NH4NO3 moves around on top of the ice.


THINGS TO TRY
-------------
1) Find the point of saturation, when no more ammonium nitrate can dissolve into the water.

2) Think about three different ways a cold pack can be designed. Example: all the NH4NO3 reacts at once or the NH4NO3 is slowly introduced

3) Test the different designs from the above question with the model.


EXTENDING THE MODEL
-------------------
1) Add a molarity plot that compares the molarity of the solution to the amount dissolved over time.

2) Add a switch that allows the NH4NO3 to be gradually added into the water solution.

3) Use the mouse-down command to let the user determine where the NH4NO3 can be added in the solution.

4) Add a slider and a button that adds another substance that had an exothermic reaction. 


CREDITS AND REFERENCES
----------------------
To refer to this model in academic publications, please use: Wilensky, U. (2003).  NetLogo Chem Cold Pack model.  http://ccl.northwestern.edu/netlogo/models/ChemColdPack. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use: Copyright 2003 by Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/ChemColdPack for terms of use.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

water
true
0
Circle -7566196 true true 61 61 176
Circle -1 true false 114 -6 70
Circle -1 true false 207 191 66

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0beta5
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@