globals [
  fast average slow              ;; current counts
  avg-speed avg-energy           ;; current averages
  clock vsplit vclock            ;; clock variables
  raw-width raw-height           ;; box size variables
  gravity                        ;; acceleration of the piston
  piston-energy total-energy     ;; current energies
  piston-height                  ;; piston variables
  piston-vel                     ;; piston speed
  area                           ;; surface area of the box below the piston
  avg-pressure                   ;; pressure on each section of the piston
  old-pressures                  ;; keep track of previous pressures so we can
                                 ;; average them over time
]

breeds [ molecules piston ]

turtles-own [
  speed mass energy                      ;; turtle info    
  v1t v1l tmp-turtle                     ;; collision info (turtle 1)
  heading2 mass2 speed2 v2t v2l turtle2  ;; collision info (turtle 2)
  theta                                  ;; collision info (both turtles)
  pressure                               ;; Pressure Vars
]

to setup
  ca
  set-default-shape molecules "circle"
  set-default-shape piston "solid"
  set raw-width  round (0.01 * box-width  * screen-edge-x)
  set raw-height round (0.01 * box-height * screen-edge-y)
  set piston-height raw-height
  make-box
  make-piston
  set piston-vel 0
  set gravity 0.125
  set clock 0
  set vclock 0
  set old-pressures []
  ;; create the gas molecules
  create-custom-molecules number [
     set speed initspeed
     set mass initmass
     random-position
     rt random-float 360
     recolor
  ]
  update-variables
  setup-plots
  do-plotting
end

to update-variables
  ;; Gas Variables
  ask molecules
    [ set energy (0.5 * mass * speed * speed) ]
  set average count molecules with [color = green]
  set slow    count molecules with [color = blue]
  set fast    count molecules with [color = red]
  if any? molecules
  [ set avg-speed  mean values-from molecules [speed]
    set avg-energy mean values-from molecules [energy]
  ]
  
  ;; Piston Variables
  set piston-energy ((0.5 * piston-mass * piston-vel * piston-vel) ;; Kinetic Energy
                    + (piston-mass * gravity * piston-height))     ;; Potential Energy
                    / max (list 1 number)  ;; calculated per molecule so it's relative to avg-energy

  ;; System Variables
  set total-energy (avg-energy + piston-energy)
  set area (4 * raw-width) + (2 * piston-height)
  calculate-pressure
  ask molecules [ set pressure 0 ]
  set vsplit max list 1 (round ((max values-from turtles [abs speed]) * 2.0))
end

to recalculate-vsplit
  ;; this needs to be done without-interruption to be sure that nothing tries to
  ;; use vsplit or vclock before they've been recalculated
  without-interruption
  [ set vsplit 2 * vsplit
    set vclock 2 * vclock
  ]
end

to go
  if piston-height < 2
  [ user-message "The piston reached the bottom of the chamber. The model will stop."
    stop
  ]
  if piston-height >= 2 * raw-height - 1
  [ user-message "The piston hit the top of the chamber. The model will stop."
    stop
  ]
  ask molecules [ bounce ]
  ask molecules [ move ]
  ;; making sure the piston moves without-intteuption removes piston flicker
  ;; and carries into exchange-energy-with-piston
  without-interruption [ move-piston ]
  set vclock (vclock + 1)
  if (vclock = vsplit)
  [ set clock (clock + 1)
    set vclock 0
    update-variables
    do-plotting
  ]
end

to bounce  ;; molecules procedure
  ; if we're not about to hit a wall (yellow patch) or piston (gray + 2 patch)
  ; we don't need to do any further checks
  if (pcolor-of patch-ahead 1 != yellow and
      pcolor-of patch-ahead 1 != gray + 2) [ stop ]

  ; check: hitting left or right wall?
  if (abs pxcor-of patch-ahead 1 = raw-width)
    ; if so, reflect heading around x axis
    [ add-left/right-pressure
      set heading (- heading) ]
      
  ; if we're not about to hit a wall (yellow patch) or piston (gray + 2 patch)
  ; we don't need to do any further checks
  if (pcolor-of patch-ahead 1 != yellow and
      pcolor-of patch-ahead 1 != gray + 2) [ stop ]

  ; check: hitting top or bottom wall? (Should never hit top, but this would handle it.)
  if (abs pycor-of patch-ahead 1 = raw-height)
  ; if so, reflect heading around y axis
  [ add-top/bottom-pressure
    set heading (180 - heading) ]
  
  ; check: hitting piston?
  if (any? value-from patch-ahead 1 [piston-here] and (speed * cos heading) > piston-vel)
  [ add-top/bottom-pressure
    ;; make sure that each molecule finishes exchanging energy before any others can
    without-interruption [ exchange-energy-with-piston ]
  ]
end

to move  ;; molecules procedure
  while [(speed / vsplit) >= 1.0]
  [ recalculate-vsplit ]
  jump (speed / vsplit)
  check-for-collision
end

to check-for-collision  ;; molecules procedure
  if count other-molecules-here = 1
  [ set tmp-turtle one-of other-molecules-here
    if ((who > who-of tmp-turtle) and (turtle2 != tmp-turtle))
    [ collide ]
  ]
end

to collide  ;; molecules procedure
  get-turtle2-info
  calculate-velocity-components
  set-new-speed-and-headings
end

to get-turtle2-info  ;; molecules procedure
  set turtle2 tmp-turtle
  set mass2 mass-of turtle2
  set speed2 speed-of turtle2
  set heading2 heading-of turtle2
end

to calculate-velocity-components
  locals [vcm]  ;; CM vel. along dir. theta
  set theta (random-float 360)
  set v1l (speed * sin (theta - heading))
  set v1t (speed * cos (theta - heading))
  set v2l (speed2 * sin (theta - heading2))
  set v2t (speed2 * cos (theta - heading2))
  set vcm (((mass * v1t) + (mass2 * v2t)) / (mass + mass2))
  set v1t (vcm + vcm - v1t)
  set v2t (vcm + vcm - v2t)
end

to set-new-speed-and-headings  ;; molecules procedure
  set speed sqrt ((v1t * v1t) + (v1l * v1l))
  set heading (theta - (atan v1l v1t))
  
  set speed-of turtle2 sqrt ((v2t * v2t) + (v2l * v2l))
  set heading-of turtle2 (theta - (atan v2l v2t))
  
  recolor
  ask turtle2 [ recolor ]
end

to recolor  ;; molecules procedure
  ifelse speed < (0.5 * initspeed)
    [ set color blue ]
    [ ifelse speed > (1.5 * initspeed)
        [ set color red ]
        [ set color green ] ]
end

to make-box
  ask patches with [((abs pxcor = raw-width) and (abs pycor <= raw-height)) or
                    ((abs pycor = raw-height) and (abs pxcor <= raw-width))]
    [ set pcolor yellow ]
end

to random-position  ;; molecules procedure
  setxy ((1 - raw-width)  + random-float (2 * raw-width - 2))
        ((1 - raw-height) + random-float (raw-height - 2))
end


;; ------ Piston ----------
to make-piston
  ask patches with [pycor = 0 and (abs pxcor < raw-width)]
  [ sprout 1
    [ set breed piston
      set color gray + 2
      set heading 0
      stamp color
      ht
    ]
  ]
end

to move-piston
  locals [old-piston-vel movement-ammount]
  set old-piston-vel piston-vel
  set piston-vel (old-piston-vel - gravity / vsplit)    ;;apply gravity
  set movement-ammount ((old-piston-vel / vsplit) - (gravity / (2 * vsplit * vsplit)))
  ;; Stamping makes the piston look like a wall to the molecules.
  ask piston
  [ stamp black
    while [(piston-vel / vsplit) >= 1.0]
    [ recalculate-vsplit ]
    ifelse piston-height + movement-ammount <= 2 * raw-height - 1
    [ fd movement-ammount
      set piston-height (raw-height + ycor-of one-of piston)
    ]
    [ set ycor raw-height - 1
      set piston-height 2 * raw-height - 1
      if piston-vel > 0
      [ set piston-vel 0 ]
    ]
    set speed piston-vel ;; just used for vsplit calculations
    stamp color
    if (piston-vel < 0) ;; piston can't hit molecules when moving upwards
    [ if (any? molecules-here with [(speed * (cos heading)) > piston-vel])
      [ ;; only bounce molecules that are moving down slower than the piston
        ;; faster ones should outrun it
        ask molecules-here with [(speed * (cos heading)) > piston-vel]
        [ add-top/bottom-pressure
          exchange-energy-with-piston
        ]
      ]
    ]
  ]
end

to exchange-energy-with-piston  ;; molecules procedure -- piston and particle exchange energy
  locals [vx vy old-vy old-piston-vel]
  set vx (speed * (sin heading))
  set vy (speed * (cos heading))         ;;only along y-axis
  set old-vy vy
  set old-piston-vel piston-vel
  set piston-vel ((((piston-mass - mass) / (piston-mass + mass)) * old-piston-vel) +
                  (((2 * mass) / (piston-mass + mass)) * old-vy))
  set vy ((((2 * piston-mass) / (piston-mass + mass)) * old-piston-vel) -
         (((piston-mass - mass) / (piston-mass + mass)) * old-vy))
  set speed (sqrt ((vx * vx) + (vy * vy)))
  set heading atan vx vy
end

;;---------------PRESSURE CALCULATIONS-------
to calculate-pressure
  ifelse (length old-pressures < 10)
  [ set old-pressures fput (sum values-from molecules [pressure]) old-pressures ]
  [ set old-pressures fput (sum values-from molecules [pressure]) butlast old-pressures ]
  if (length old-pressures > 0)
  [ set avg-pressure mean old-pressures
    set avg-pressure ((avg-pressure) / area) ]
end

to add-top/bottom-pressure ;; molecules procedure
  set pressure pressure + abs (cos heading * mass * speed)
end

to add-left/right-pressure ;; molecules procedure
  set pressure pressure + abs (sin heading * mass * speed)
end

;;; plotting procedures
to setup-plots
  ;; Piston height plot
  set-current-plot "Piston Height"
  set-plot-y-range 0 (2 * raw-height)
   
  ;; Energy plot
  set-current-plot "Energy"
  set-plot-y-range 0 max list 1 (avg-energy * 2)
end

to do-plotting
  plot-piston-height
  plot-energy
  plot-the-pressures  
end

to plot-piston-height
  set-current-plot "Piston Height"
  set-current-plot-pen "height"
  plot piston-height
end

to plot-energy
  set-current-plot "Energy"
  set-current-plot-pen "gas"
  plot avg-energy
  set-current-plot-pen "piston"
  plot piston-energy
  set-current-plot-pen "total"
  plot total-energy
end

to plot-the-pressures
  set-current-plot "Pressure"
  set-current-plot-pen "pressure"
  plot avg-pressure
end


; *** NetLogo Model Copyright Notice ***
;
; This model was originally created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky. All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo (and was changed in the process to
; be an alternate version of the model) as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
; Converted from StarLogoT to NetLogo, 2001.  Updated 2002.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo GasLab Adiabatic Piston model.
; http://ccl.northwestern.edu/netlogo/models/GasLabAdiabaticPiston.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/GasLabAdiabaticPiston
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
171
10
505
365
40
40
4.0
0
10
1
1
1

CC-WINDOW
9
381
299
548
Command Center

BUTTON
94
41
165
74
go
go
T
1
T
OBSERVER
NIL

BUTTON
9
41
85
74
setup
setup
NIL
1
T
OBSERVER
T

MONITOR
410
499
505
548
avg-energy
avg-energy
3
1

MONITOR
410
440
505
489
NIL
piston-energy
3
1

MONITOR
9
321
65
370
clock
clock
3
1

MONITOR
410
381
505
430
NIL
total-energy
3
1

MONITOR
307
499
403
548
avg-speed
avg-speed
3
1

MONITOR
307
381
403
430
NIL
piston-height
3
1

MONITOR
307
440
403
489
piston-velocity
piston-vel
3
1

SLIDER
9
84
165
117
box-height
box-height
20
100
95.0
1.0
1
%

SLIDER
9
117
165
150
box-width
box-width
20
100
75.0
1.0
1
%

SLIDER
9
235
165
268
initmass
initmass
1.0
20.0
1.0
1.0
1
NIL

SLIDER
9
278
165
311
piston-mass
piston-mass
100.0
5000.0
4000.0
100.0
1
NIL

SLIDER
9
159
165
192
number
number
0
1500
200
1
1
molecules

SLIDER
9
202
165
235
initspeed
initspeed
0.0
20.0
10.0
1.0
1
NIL

PLOT
507
41
724
211
Piston Height
Time
Height
0.0
50.0
0.0
76.0
true
false
PENS
"height" 1.0 0 -16776961 true

PLOT
507
211
724
381
Pressure
Time
Pressure
0.0
50.0
0.0
10.0
true
false
PENS
"pressure" 1.0 0 -65536 true

PLOT
507
381
743
548
Energy
Time
Energy
0.0
50.0
0.0
50.0
true
true
PENS
"gas" 1.0 0 -65536 true
"piston" 1.0 0 -16776961 true
"total" 1.0 0 -16777216 true

@#$#@#$#@
WHAT IS IT?
-----------
This model is part of the GasLab collection of models.  See GasLab Gas in a Box for an introduction to the GasLab collection.

This model simulates the behavior of gas molecules in a box with a movable piston. The piston has weight which pushes it down, and the gas molecules push upward against the piston when they collide with it.

"Adiabatic" means "without loss or gain of heat".  In this model, no heat energy (such as heat loss through the walls of the box) is added to or removed from the system.


HOW IT WORKS
------------
For the basics of how all GasLab models work, see GasLab Gas in a Box.

The piston has both potential energy (due to gravity) and kinetic energy (from its motion).

Each particle bounces off the sides and the bottom of the box without changing speed.  When it hits the piston, however, its speed does change.  If the piston is moving upward at that moment, the particle bounces off at a slightly smaller speed.  If the piston is moving downward, it gives the particle a kick and the particle speeds up.  This is the process by which the energy of the gas is changed by the motion of the piston.

The piston also changes speed with each collision.  The change is not large, because the piston is much heavier than each particle; but the accumulated effect of many particle collisions is enough to hold the piston up.

Gravity is incorporated in this model as a constant downwards acceleration on the piston.  In order to make the model simpler, this model doesn't include the effect of gravity on the molecules.  See the GasLab Atmosphere and GasLab Gravity Box models if you are interested in the effect of gravity on the molecules.

Pressure is calculated by adding up the momentum transferred to the walls of the box and the piston by the molecules when they bounce off.  This is averaged over the surface area of the box to give the pressure.


HOW TO USE IT
-------------
Initial settings:
- BOX-HEIGHT: height of the container. (percentage of the screen height)
- BOX-WIDTH: width of the container.  (percentage of the screen width)
- NUMBER: number of gas molecules.
- INITSPEED: initial speed of the molecules.
- INITMASS: mass of each molecule.
- PISTON-MASS: mass of the piston, in the same "units" as the molecular mass.

The SETUP button will set the initial conditions.  The GO button will run the simulation.

Monitors:
- AVG-SPEED: average speed of the molecules.
- PISTON-VEL: speed of the piston (up is positive).
- PISTON-HEIGHT: piston's height above the bottom of the box.
- AVG-ENERGY: average kinetic energy per molecule of the gas.
- PISTON-ENERGY: sum of potential and kinetic energy of the piston, calculated per molecule, so that it's comparable to avg-energy.
- TOTAL-ENERGY: sum of avg-energy and piston-energy.
- CLOCK: number of ticks that have run.

Plots:
- PISTON HEIGHT: measured up from the bottom of the box.
- PRESSURE: average pressure of the molecules.
- ENERGY OF MOLECULES, PISTON, AND TOTAL ENERGY: in terms of energy per particle.  The piston's energy is both kinetic (motion) and potential (height).


THINGS TO NOTICE
----------------
Watch all the plots and notice how they change in relation to each other.

Does the piston reach an equilibrium position?  What is the pattern of its motion before that?  Why doesn't it keep oscillating, like a bouncing ball, if all of the collisions are elastic?

Would you expect that the pressure would settle at a stable value?  What would determine it?

The energy of the gas changes as the piston moves up and down.  How are the two related?   Where does the energy come from and where does it go?

Can you infer what is happening to the temperature of the gas as the piston moves?

Explain in physical terms and in terms of the model's rules how the piston heats up the gas by pushing downward and cools it down when moving upward.

Gravity only affects the piston in this model.  Does this make sense?  If gravity were made to affect the molecules as well would that significantly change the behavior of the model?  What if you were to think of the downwards acceleration of the piston as the atmospheric pressure pushing down from above the piston.  Would this make more sense?  Would you need to make any changes to the behavior of the model to have the force be atmospheric pressure instead of gravity?  Why or why not?

You can change the coloring of the molecules while it's running by moving the INITSPEED slider.  This will change the meaning of the colors, but not the relative meanings of the colors or the behavior of the model.


THINGS TO TRY
-------------
Change the initial particle mass and particle speed.  How do these variables affect the piston's motion and its equilibrium position?  Adjust the piston's mass to keep it inside the box.

Change the piston mass, leaving the gas alone.  What happens to all of the volume, pressure, and energy?  Note: if you do this while the model is running, the piston energy changes suddenly.  Why is this?

In this simulation, the piston and the molecules exchange energy on every collision.  The model treats the wall collisions differently. Is this legitimate?  How is a piston different from a wall?

In this adiabatic system, neither pressure, volume, nor temperature are constant, so pressure and volume are not simply inversely proportional.  In fact it turns out that for two different states,

|   (P'/P) = (V/V')^gamma,

where gamma depends on the number of degrees of freedom of the molecules.   In this two-dimensional case, gamma = 2.  Confirm that this is roughly true by changing piston-mass (hence pressure) and noticing its effect on piston height (hence volume).


EXTENDING THE MODEL
-------------------
Add a heater in the box that changes the temperature of the gas.  What would happen if the gas were heated and nothing else were changed?

Combine this with the "Two Gas" model such that there are gases pushing on both sides of a piston, instead of gravity against a single gas.

Give the piston the ability to store thermal energy, so that it heats up instead of moving when the molecules hit it.


RELATED MODELS
--------------
Look at the other GasLab models, especially Isothermal Piston and Moving Piston.


CREDITS AND REFERENCES
----------------------
Wilensky, U. (1999). GasLab--an Extensible Modeling Toolkit for Exploring Micro- and Macro- Views of Gases. In Roberts, N. , Feurzeig, W. & Hunter, B. (Eds.) Computer Modeling and Simulation in Science Education. Berlin: Springer Verlag.  (this is the best and most detailed source) 

Wilensky, U. & Resnick, M. (1999). Thinking in Levels: A Dynamic Systems Perspective to Making Sense of the World. Journal of Science Education and Technology. Vol. 8 No. 1 

Wilensky, U., Hazzard, E. & Froemke, R. (1999). An Extensible Modeling Toolkit for Exploring Statistical Mechanics Proceedings of the Seventh European Logo Conference - EUROLOGO'99, Sofia, Bulgaria.  

To refer to this model in academic publications, please use: Wilensky, U. (2002). NetLogo GasLab Adiabatic Piston model. http://ccl.northwestern.edu/netlogo/models/GasLabAdiabaticPiston. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use: Copyright 2002 by Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/GasLabAdiabaticPiston for terms of use.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 300 300 150 195 150 195 7 105 7 105 150 105 150 0 150

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

solid
false
0
Rectangle -7566196 true true 0 1 317 316

spacecraft
true
0
Polygon -7566196 true true 150 300 120 165 45 45 75 60 150 120 225 60 255 45 180 165

thin-arrow
true
0
Polygon -7566196 true true 150 300 300 150 180 150 180 4 120 4 120 150 120 150 0 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0beta5
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@