globals [
  fast average slow     ;; current counts
  avg-speed avg-energy  ;; current averages
  clock vsplit vclock   ;; clock variables
  raw-width raw-height  ;; box size variables
  piston-position
  volume area           ;; because this is 2D, area is the perimeter and volume is the area
  avg-pressure          ;; pressure on each section of the piston
  prhistory 
  run-go?               ;; flag of whether or not its safe for go to run
]

turtles-own [
  speed mass energy new-speed            ;; Turtle Info    
  v1t v1l tmp-turtle                     ;; Turtle 1 -- Collide   
  heading2 mass2 speed2 v2t v2l turtle2  ;; Turtle 2 -- Collide
  theta                                  ;; Turtles 1 + 2 -- Collide
  pressure ptop pright pbottom pleft     ;; Pressure Vars
]

to setup 
  ca
  set run-go? true
  set raw-width  round (0.01 * box-width  * screen-edge-x)
  set raw-height round (0.01 * box-height * screen-edge-y)
  set piston-position 0
  set area ((4 * raw-width) + (2 * (piston-position + raw-height)))
  set volume ((2 * raw-width) * (piston-position + raw-height))
  make-box
  draw-piston
  set clock  0
  set vclock 0
  set prhistory []
  ;; create the gas molecules
  cct number [
     set new-speed initspeed
     set mass initmass
     random-position
     rt random-float 360
     set shape "circle"
     recolor
     zero-pressures
  ]
  update-variables
  setup-plots
  setup-histograms
  do-plotting
  do-histograms
end

to update-variables
  ;; Gas Variables
  ask turtles
    [ set speed new-speed
      set pressure (ptop + pright + pbottom + pleft)
      zero-pressures  ;; Reset pressure components for next clock tick
      set energy (0.5 * mass * speed * speed) ]
  set average count turtles with [ color = green ]
  set slow    count turtles with [ color = blue  ]
  set fast    count turtles with [ color = red   ]
  set avg-speed  mean values-from turtles [ speed  ]
  set avg-energy mean values-from turtles [ energy ]
  
  ;; System Variables
  calculate-pressure
  set vsplit (round (max values-from turtles [speed] * 1.2))
end

to go
  if (not run-go?) [ stop ]
  ask turtles [bounce]
  ask turtles [move]
  set vclock (vclock + 1)
  if (vclock = vsplit)
  [ set clock  (clock + 1)
    set vclock 0
    update-variables
    do-plotting
    do-histograms
  ]
end

to bounce ;; turtle procedure
  ; if we're not about to hit a wall (yellow patch)
  ; or the piston (gray+2 patch),
  ; we don't need to do any further checks
  if (pcolor-of patch-ahead 1 != yellow) and
     (pcolor-of patch-ahead 1 != gray + 2) [ stop ]
  ; check: hitting left or right wall?
  if (abs pxcor-of patch-ahead 1 = raw-width)
    ; if so, reflect heading around x axis
    [ press-left/right
      set heading (- heading) ]
  ; check: hitting piston or bottom wall?
  if (abs pycor-of patch-ahead 1 = raw-height) or
     (pycor-of patch-ahead 1 = round piston-position)
    ; if so, reflect heading around y axis
    [ press-top/bottom
      set heading (180 - heading) ]
end

to move  ;;turtle procedure
  jump (speed / vsplit)
  check-for-collision
end

to check-for-collision  ;;turtle procedure
  if count other-turtles-here = 1
    [ set tmp-turtle one-of other-turtles-here
      if ((who > who-of tmp-turtle) and (turtle2 != tmp-turtle))
        [ collide ]
    ]
end

to collide  ;;turtle procedure
  get-turtle2-info
  calculate-velocity-components
  set-new-speed-and-headings
end

to get-turtle2-info  ;;turtle procedure
  set turtle2 tmp-turtle
  set mass2 mass-of turtle2
  set speed2 new-speed-of turtle2
  set heading2 heading-of turtle2
end

to calculate-velocity-components
  locals [ vcm ]  ;; CM vel. along dir. theta
  set theta (random-float 360)
  set v1l (new-speed * sin (theta - heading))
  set v1t (new-speed * cos (theta - heading))
  set v2l (speed2 * sin (theta - heading2))
  set v2t (speed2 * cos (theta - heading2))
  set vcm (((mass * v1t) + (mass2 * v2t)) / (mass + mass2))
  set v1t (vcm + vcm - v1t)
  set v2t (vcm + vcm - v2t)
end

to set-new-speed-and-headings  ;;turtle procedure
  set new-speed sqrt ((v1t * v1t) + (v1l * v1l))
  set heading (theta - (atan v1l v1t)) 

  set new-speed-of turtle2 sqrt ((v2t * v2t) + (v2l * v2l))
  set heading-of turtle2 (theta - (atan v2l v2t))

  recolor
  ask turtle2 [ recolor ]
end

to recolor  ;; turtle procedure
  ifelse new-speed < (0.5 * initspeed)
    [ set color blue ]
    [ ifelse new-speed > (1.5 * initspeed)
        [ set color red ]
        [ set color green ] ]
end

to make-box
  ask patches with [ ((abs pxcor = raw-width) and (abs pycor <= raw-height)) or
                     ((abs pycor = raw-height) and (abs pxcor <= raw-width)) ]
    [ set pcolor yellow ]
end

to random-position  ;; turtle procedure
  setxy ((1 - raw-width)  + random-float (2 * raw-width - 2))
        ((1 - raw-height) + random-float (raw-height - 2))
end


;; ------ Piston ----------
to move-piston
  set run-go? false
  if (mouse-down?)
   [ ifelse (mouse-ycor < piston-position)
      [ piston-down (piston-position - mouse-ycor) ]
      [ piston-up (mouse-ycor - piston-position) ]
     set run-go? true
     stop
   ]
end

to piston-up [dist]
  if (dist > 0)
  [ ifelse ((piston-position + dist) < raw-height - 1)
    [ undraw-piston
      set piston-position (piston-position + dist)
      draw-piston ]
    [ undraw-piston
      set piston-position (raw-height - 1)
      draw-piston ]
    set prhistory []
    set volume ((2 * raw-width) * (piston-position + raw-height))
    set area ((4 * raw-width) + (2 * (piston-position + raw-height)))
  ]
end

to piston-down [dist]
  if (dist > 0)
  [ ifelse (piston-position - dist) > (2 - raw-height)
    [ undraw-piston
      set piston-position (piston-position - dist)
      ask turtles
      [ if (ycor >= (piston-position - 1))
        [ bounce-off-piston ] ]
      draw-piston ]
    [ undraw-piston
      set piston-position (3 - raw-height)
      ask turtles
      [ if (pycor >= 3 - raw-height)
        [ bounce-off-piston ] ]
      draw-piston ]
    set prhistory []
    set area ((4 * raw-width) + (2 * (piston-position + raw-height)))
    set volume ((2 * raw-width) * (piston-position + raw-height))
  ]
end

to draw-piston
  ask patches with [ ((pycor = (round piston-position)) and ((abs pxcor) < raw-width)) ]
    [ set pcolor gray + 2 ]
end

to undraw-piston
  ask patches with [ (pycor = round piston-position) and ((abs pxcor) < raw-width) ]
    [ set pcolor black ]
end

to bounce-off-piston  ;; Turtles procedure particle bounces off piston
  ifelse ((((2 * piston-position) - (ycor + 2)) < (1 - raw-height)) or
          (((2 * piston-position) - (ycor + 2)) > (piston-position - 2)))
   [ set ycor ((random (raw-height + piston-position - 2)) - (raw-height - 1)) ]
   [ set ycor ((2 * piston-position) - (ycor + 2)) ]
end


;;---------------PRESSURE CALCULATIONS-------
to zero-pressures
  set ptop 0
  set pbottom 0
  set pright 0
  set pleft 0
end

to calculate-pressure  ;; Observer procedure
  ifelse (length prhistory < 10)
  [ set prhistory fput (sum values-from turtles [ pressure ]) prhistory ]
  [ set prhistory fput (sum values-from turtles [ pressure ]) butlast prhistory ]
  if (length prhistory > 0)
  [ set avg-pressure sum prhistory / length prhistory
    set avg-pressure ((100 * avg-pressure) / area) ]
end

to press-top/bottom
  ifelse (heading > 270) or (heading < 90)
   [ set ptop    ptop    + (cos heading * mass * new-speed) ]
   [ set pbottom pbottom - (cos heading * mass * new-speed) ]
end

to press-left/right
  ifelse (heading < 180)
   [ set pright pright + (sin heading * mass * new-speed) ]
   [ set pleft  pleft  - (sin heading * mass * new-speed) ]
end

;;; plotting procedures

to setup-plots
  set-current-plot "Volume"
  set-plot-y-range 0 (volume * 2)
end

to setup-histograms

  ;; Speed Histogram
  set-current-plot "Speed histogram"
  set-plot-x-range 0 (initspeed * 2)
  set-plot-y-range 0 ceiling (number / 6)
  set-current-plot-pen "average"
  set-histogram-num-bars 45
  set-current-plot-pen "fast"
  set-histogram-num-bars 45
  set-current-plot-pen "slow"
  set-histogram-num-bars 45

  ;; Energy histogram
  set-current-plot "Energy histogram"
  set-plot-x-range 0 (0.5 * (initspeed * 2) * (initspeed * 2) * initmass)
  set-plot-y-range 0 ceiling (number / 6) 
  set-current-plot-pen "average"
  set-histogram-num-bars 45
  set-current-plot-pen "fast"
  set-histogram-num-bars 45
  set-current-plot-pen "slow"
  set-histogram-num-bars 45
end

;; does actual plotting (called in Go)
to do-plotting
  plot-volume
  plot-the-pressures  
end

;; does actual histograms plotting (called in Go)
to do-histograms
  if (histogram?)
    [ histo-energy
      histo-speed ]
end

to plot-volume
  set-current-plot "Volume"
  set-current-plot-pen "volume"
  plot volume
end

to plot-the-pressures
  set-current-plot "Pressure"
  set-current-plot-pen "pressure"
  plot avg-pressure
end

;; draw energy histogram
to histo-energy
  set-current-plot "Energy histogram"
  set-current-plot-pen "average"
  histogram-from turtles with [ color = green ] [ energy ]
  set-current-plot-pen "slow"
  histogram-from turtles with [ color = blue ] [ energy ]
  set-current-plot-pen "fast"
  histogram-from turtles with [ color = red ] [ energy ]
  set-current-plot-pen "avg-energy"
  plot-pen-reset
  draw-vert-line avg-energy
end


;; draw speed histogram
to histo-speed
  set-current-plot "Speed histogram"
  set-current-plot-pen "average"
  histogram-from turtles with [ color = green ] [ speed ]
  set-current-plot-pen "slow"
  histogram-from turtles with [ color = blue ] [ speed ]
  set-current-plot-pen "fast"
  histogram-from turtles with [ color = red ] [ speed ]
  set-current-plot-pen "avg-speed"
  plot-pen-reset
  draw-vert-line avg-speed
end

; draws a vertical line at xval on the current-plot with the current plot-pen
to draw-vert-line [xval]
  plotxy xval plot-y-min
  plot-pen-down
  plotxy xval plot-y-max
  plot-pen-up
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky. All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
; Converted from StarLogoT to NetLogo, 2001.  Updated 2002.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo GasLab Isothermal Piston model.
; http://ccl.northwestern.edu/netlogo/models/GasLabIsothermalPiston.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/GasLabIsothermalPiston
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
260
10
594
365
40
40
4.0
0
10
1
1
1

CC-WINDOW
9
331
256
457
Command Center

BUTTON
73
41
128
74
go
go
T
1
T
OBSERVER
NIL

BUTTON
137
41
256
74
move-piston
move-piston
T
1
T
OBSERVER
T

BUTTON
9
41
64
74
setup
setup
NIL
1
T
OBSERVER
T

SWITCH
9
170
128
203
histogram?
histogram?
0
1
-1000

MONITOR
173
272
256
321
avg-energy
avg-energy
3
1

MONITOR
81
272
164
321
avg-pressure
avg-pressure
3
1

MONITOR
9
213
63
262
clock
clock
3
1

MONITOR
81
213
164
262
piston-pos
piston-position
3
1

MONITOR
173
213
256
262
volume
volume
3
1

SLIDER
137
84
256
117
box-height
box-height
20
100
95
1
1
%

SLIDER
137
127
256
160
box-width
box-width
20
80
75
1
1
%

SLIDER
9
127
128
160
initmass
initmass
1.0
30.0
4.0
1.0
1
NIL

SLIDER
9
84
128
117
initspeed
initspeed
2.0
10.0
5.0
1.0
1
NIL

SLIDER
137
170
256
203
number
number
1
4000
400
1
1
NIL

PLOT
598
41
807
198
Volume
Time
Volume
0.0
20.0
0.0
4560.0
true
false
PENS
"volume" 1.0 0 -6524078 true

PLOT
598
208
807
365
Pressure
Time
Pressure
0.0
20.0
0.0
1000.0
true
false
PENS
"pressure" 1.0 0 -65536 true

PLOT
380
375
589
532
Speed histogram
Time
Number
0.0
10.0
0.0
67.0
false
false
PENS
"fast" 1.0 1 -65536 true
"average" 1.0 1 -11352576 true
"slow" 1.0 1 -16776961 true
"avg-speed" 1.0 0 -7566196 true

PLOT
598
375
807
532
Energy histogram
Time
Number
0.0
200.0
0.0
67.0
false
false
PENS
"fast" 1.0 1 -65536 true
"average" 1.0 1 -11352576 true
"slow" 1.0 1 -16776961 true
"avg-energy" 1.0 0 -7566196 true

@#$#@#$#@
WHAT IS IT?
-----------
This program simulates the behavior of gas molecules in a box with a piston.  It is part of the Connected Mathematics "Making Sense of Complex Phenomena" Modeling Project.  

The volume in which the gas is contained can be changed by moving the piston up and down.  "Isothermal" means that the temperature of the gas is not changed by moving the piston.  

The Isothermal Piston model is one in a collection  of GasLab models that all use the same basic rules for expressing what happens when gas molecules collide.  Each of the GasLab models has different features in order to show different aspects of the behavior of gases.  

Molecules are modeled as single particles, all with the same mass and initial velocity. Molecules are modeled as perfectly elastic particles with no internal energy except that which is due to their motion.  Collisions with the box and between molecules are elastic. Particles are colored according to speed -- blue for slow, green for medium, and red for high speeds.  

The exact way two molecules collide is as follows: 
1.  Two turtles "collide" if they find themselves on the same patch.
2.  A random axis is chosen, as if they were two balls that hit and this axis were the line connecting their centers.
3.  They exchange momentum and energy along that axis, according to the conservation of momentum and energy.  This calculation is done in the center of mass system.
4. Each turtle is assigned its new speed, energy, and heading.
5.  If a turtle finds itself on or very close to a wall of the container, it "bounces" -- that is, reflects its direction and keeps its same speed.  

Pressure is calculated by adding up the momentum transferred to the walls of the box by the molecules when they bounce off.  This is averaged over all of the walls to give the pressure.  


HOW TO USE IT
-------------
Initial settings:
INITSPEED - initial speed of the molecules
INITMASS - initial mass of the molecules
NUMBER - number of molecules
BOX-HEIGHT - height of the container
BOX-WIDTH - width of the container
HISTOGRAM? - turns histogramming on or off
  
The SETUP button will set the initial conditions.  The GO button will run the simulation.  

Pushing the MOVE-PISTON button allows you to reposition the piston with the mouse, hence changing the volume. Once the reposition is done, push the GO button to continue.

The intention in this model is for the user to quickly pull the piston up thus simulating quickly removing a plate. This means no particles collide with the piston as it is removed. However, we have left in code that allows the user to push the piston down and compress the gas. In this model, though, the  collisions of the piston with the particles are ignored. Note that there's a physical impossibility in the model here:  in real life if you moved the piston down you would do work on the gas by compressing it, and its temperature would increase.  In this model the energy and temperature are constant no matter how you manipulate the piston, hence the name "isothermal".  Nonetheless, the basic relationship between volume and pressure is correctly demonstrated here.

The physically accurate version of piston compression is shown in the "Adiabatic Piston" model.

As the simulation runs you can view histograms of the speed and the energy distribution of the molecules in the plot. 
There are also plots of the volume and pressure of the box, as line graphs in the plots. 


THINGS TO NOTICE
----------------

How does the pressure change as you change the volume of the box by moving the piston?  Compare the two plots of volume and pressure.
  
Measure changes in pressure and volume. Is there a clear quantitative relationship? 

How can the relationship between pressure and volume be explained in terms of the collisions of molecules?

What shapes do the energy and velocity histograms reach after a while?  Why aren't they the same?  Do the pressure and volume affect these shapes?


THINGS TO TRY
-------------
How would you calculate pressure?  How does this code do it? 

Change the number, mass, and initial velocity of the molecules.  Does this affect the pressure?   Why? Do the results make intuitive sense?  Look at the extremes:  very few or very many molecules,  high or low volumes.  

Figure out how many molecules there REALLY are in a box this size -- say a 10-cm cube.  Look up or calculate the REAL mass and speed of a typical molecule.  When you compare those numbers to the ones in the model, are you surprised this model works as well as it does?


EXTENDING THE MODEL
-------------------

Are there other ways one might calculate pressure?  

When the piston is moved upward, the gas is not evenly distributed for a while.  What's the pressure during this time?  Does this ever happen in the real world?   What does pressure mean when it's not the same throughout a gas?  


NETLOGO FEATURES
----------------  

Notice how collisions are detected by the turtles and how the code guarantees that the same two particles do not collide twice.  What happens if we let the patches detect them?


CREDITS AND REFERENCES
----------------------
To refer to this model in academic publications, please use: Wilensky, U. (1998).  NetLogo GasLab Isothermal Piston model. http://ccl.northwestern.edu/netlogo/models/GasLabIsothermalPiston. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use: Copyright 1998 by Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/GasLabIsothermalPiston for terms of use.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 300 300 150 195 150 195 7 105 7 105 150 105 150 0 150

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

spacecraft
true
0
Polygon -7566196 true true 150 300 120 165 45 45 75 60 150 120 225 60 255 45 180 165

thin-arrow
true
0
Polygon -7566196 true true 150 300 300 150 180 150 180 4 120 4 120 150 120 150 0 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0alpha2
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@