globals [
  fast average slow        ;; current counts
  avg-speed avg-energy     ;; current averages
  clock vsplit vclock      ;; clock variables
  raw-width raw-height     ;; position of the box walls
  width height             ;; dimensions of gas chamber
  volume area              ;; size of gas chamber
  total-pressure           ;; average of pressure inside the box
  pressure-history         ;; previous pressure values
  initspeed initmass       ;; initial speed and mass of particles
  wall-position            ;; position of the gray wall
  wall-speed               ;; speed of the gray wall
  walls                    ;; holds the wall patches
  was-locked?              ;; whether the wall was previously locked
]

turtles-own [
  speed mass energy                     ;; turtle info
  v1t v1l tmp-turtle                    ;; collision info (turtle 1)
  heading2 mass2 speed2 v2t v2l turtle2 ;; collision info (turtle 2)
  theta                                 ;; collision info (both turtles)
  pressure                              ;; pressure vars
]

;; The setup reads all the variables for the setup of the box and particles.
to setup
  ca
  set raw-width  round (0.90 * screen-edge-x)
  set raw-height round (0.80 * screen-edge-y)
  set wall-position 0
  set was-locked? wall-is-locked?
  set width raw-width - 1
  set height 2 * raw-height - 1
  set wall-speed 0
  make-box
  draw-wall
  set initspeed 10.0
  set initmass 1.0
  set clock 0
  set vclock 0
  set pressure-history []
  cct number
  [
    set speed initspeed
    set mass initmass
    random-position
    rt random-float 360
    set shape "circle"
    recolor
  ]
  update-variables
  setup-plots
  do-plotting
end

;; procedure to ask all turtles to update their energy/speed and
;; also update the pressure inside the box
to update-variables
  ask turtles
    [ set energy (0.5 * mass * speed * speed) ]
  set average count turtles with [color = green]
  set slow    count turtles with [color = blue]
  set fast    count turtles with [color = red]
  
  if any? turtles
  [
    set avg-speed  mean values-from turtles [speed]
    set avg-energy mean values-from turtles [energy]
    set total-pressure sum values-from turtles [pressure]
  ]
  
  set width wall-position + raw-width - 1
  set area 2 * width + 2 * height
  set volume width * height
  calculate-pressure
  ask turtles [ set pressure 0 ]
  set vsplit max list 1 (round ((max values-from turtles [speed]) * 1.2))
end

;; vsplit allows for the particles of different speeds to travel in a path that
;; will ensure a collision between particles if they are on the same patch
to recalculate-vsplit
  ;; this needs to be done without-interruption to be sure that nothing tries to
  ;; use vsplit or vclock before they've been recalculated
  without-interruption
  [ set vsplit 2 * vsplit
    set vclock 2 * vclock
  ]
end

;; runs the simulation
;; determines wall speed and how the inside and outside pressure move the wall.
to go
  ask turtles [ bounce ]
  ask turtles [ move ]
  ifelse wall-is-locked?
  [ 
    if not was-locked?
    [ set was-locked? true
      draw-wall
    ]
    ask walls with [pxcor != (round wall-position)]
    [ set pcolor temperature-color ]
  ]
  [ if was-locked? [ set was-locked? false ]
    ask walls [ set pcolor temperature-color ]
    if (outside-pressure > total-pressure and wall-speed > (- avg-speed))
    [ 
      set wall-speed wall-speed - 1
    ]
    if (total-pressure > outside-pressure and wall-speed < avg-speed)
    [
      set wall-speed wall-speed + 1
    ]
    if wall-speed > 0
    [
      wall-right wall-speed / vsplit 
    ]
    if wall-speed < 0
    [
      wall-left (- wall-speed) / vsplit
    ]
  ]
  
  set vclock (vclock + 1)
  if (vclock = vsplit)
  [ set clock (clock + 1)
    set vclock 0
    update-variables
    do-plotting 
    do-histograms
  ]
end

;; a turtle procedure that keeps the particles inside the box and 
;; also recalculates the energy and direction after the bounce
to bounce  
  locals [ new-px new-py ]
  ; if we're not about to hit a box wall (red patch) or 
  ; the moveable wall (gray+2 patch) we don't need to do any more checks
  if (not shade-of? red pcolor-of patch-ahead 1) and
     (pcolor-of patch-ahead 1 != gray + 2)  [ stop ]
  ; get the coordinates of the patch we'll be on if we go forward 1
  set new-px pxcor-of patch-ahead 1
  set new-py pycor-of patch-ahead 1
  
  ; check: hitting left or right wall?
  if (abs new-px = raw-width) or (new-px = round wall-position)
    ; if so, reflect heading around x axis
    [ set heading (- heading)
      set pressure pressure + abs (sin heading * mass * speed)
      set energy mean list energy outside-temperature
      set speed sqrt (2 * energy / mass)
      recolor
    ]
  ; check: hitting top or bottom wall?
  if (abs new-py = raw-height)
    ; if so, reflect heading arouny y axis
    [ set heading (180 - heading)
      set pressure pressure + abs (cos heading * mass * speed)
      set energy mean list energy outside-temperature
      set speed sqrt (2 * energy / mass)
      recolor
    ]
end

;; turtle procedure used to move turtles using the vsplit modification
to move  ;; turtle procedure
  while [(speed / vsplit) >= 1.0]
  [ recalculate-vsplit ]
  jump (speed / vsplit)
  check-for-collision
end

;; turtle procedure to check and see if turtle will collide with other turtles 
;; if they move forward
to check-for-collision 
  if count other-turtles-here = 1
  [ set tmp-turtle random-one-of other-turtles-here
    if ((who > who-of tmp-turtle) and (turtle2 != tmp-turtle))
    [ collide ]
  ]
end

;;turtle collision procedure
to collide 
  get-turtle2-info
  calculate-velocity-components
  set-new-speed-and-headings
end

to get-turtle2-info  ;; turtle procedure
  set turtle2 tmp-turtle
  set mass2 mass-of turtle2
  set speed2 speed-of turtle2
  set heading2 heading-of turtle2
end

;; turtle procedure that calculates the speed of the two turtles
;; before they collide
to calculate-velocity-components
  locals [vcm]  ;; CM vel. along dir. theta
  set theta (random-float 360)
  set v1l (speed * sin (theta - heading))
  set v1t (speed * cos (theta - heading))
  set v2l (speed2 * sin (theta - heading2))
  set v2t (speed2 * cos (theta - heading2))
  set vcm (((mass * v1t) + (mass2 * v2t)) / (mass + mass2))
  set v1t (vcm + vcm - v1t)
  set v2t (vcm + vcm - v2t)
end

;; turtle procedure that sets new speed and headings used for after 
;; the collision of two turtles.
to set-new-speed-and-headings  
  set speed sqrt ((v1t * v1t) + (v1l * v1l))
  set heading (theta - (atan v1l v1t))
  
  set speed-of turtle2 sqrt ((v2t * v2t) + (v2l * v2l))
  set heading-of turtle2 (theta - (atan v2l v2t))
  
  recolor
  ask turtle2 [ recolor ]
end

;; turtle procedure to recolor the turte to its new speed color 
;; after a collision
to recolor  
  ifelse speed < (0.5 * initspeed)
    [ set color blue ]
    [ ifelse speed > (1.5 * initspeed)
        [ set color red ]
        [ set color green ] ]
end

;; patch procedure to make the box
to make-box
  set walls patches with [ ((pxcor = (- raw-width)) and (abs pycor <= raw-height)) or
                           ((pxcor = raw-width) and (abs pycor = (raw-height - 1))) or
                           ((abs pycor = raw-height) and (abs pxcor <= raw-width)) ]
  ask walls
  [ set pcolor temperature-color ]
  set plabel-of patch raw-width raw-width "outside"
end

to random-position  ;; turtle procedure
  setxy (1 - raw-width  + random-float (width - 1))
        (1 - raw-height + random-float (height - 1))
end

to-report temperature-color
  report scale-color red outside-temperature -200 600
end

;; moveable wall
to undraw-wall
  no-display
  ask patches with [(pxcor = round wall-position) and (abs pycor < raw-height)]
    [ set pcolor black ]
  ask patches with [(pxcor = round wall-position) and (abs pycor = raw-height)]
    [ set pcolor temperature-color ]
end

to draw-wall
  ask patches with [(pxcor = round wall-position) and (abs pycor < raw-height)]
    [ set pcolor gray + 2 ]
  if wall-is-locked?
  [
    ask patches with [(pxcor = round wall-position) and (abs pycor = raw-height)]
      [ set pcolor gray + 2 ]
  ]
  display
end

;;this procedure ensures that the wall will not move past the already defined edges of the box
to bounce-off-wall
  ifelse ( ( ((2 * wall-position) - (xcor + 2)) < (1 - raw-width) ) or
           ( ((2 * wall-position) - (xcor + 2)) > (wall-position - 2)) )
    [ set xcor ((random-float (raw-width + wall-position - 2)) - (raw-width - 1)) ]
    [ set xcor ((2 * wall-position) - (xcor + 2)) ]
end

to wall-right [dist]
  if (dist > 0)
  [ ifelse (wall-position < raw-width - 1)
    [ undraw-wall
      set wall-position (wall-position + dist)
      draw-wall
    ]
    [ undraw-wall
      set wall-position (raw-width - 1)
      set wall-speed 0
      draw-wall
    ]
    set width wall-position + raw-width - 1
    set volume width * height
    set area 2 * width + 2 * height
  ]
end

;; wall movement procedure
to wall-left [dist]
  if (dist > 0)
  [ ifelse (wall-position - dist) > (2.5 - raw-width)
    [ undraw-wall
      set wall-position (wall-position - dist)
      ask turtles
      [ if (xcor >= (wall-position - 1))
        [ bounce-off-wall ]
      ]
      draw-wall
    ]
    [ undraw-wall
      set wall-position (3 - raw-width)
      set wall-speed 0
      ask turtles
      [ if (pxcor >= 3 - raw-width)
        [ bounce-off-wall ]
      ]
      draw-wall
    ]
    set width wall-position + raw-width - 1
    set volume width * height
    set area 2 * width + 2 * height
  ]
end

;;; pressure calculations
to calculate-pressure
  set total-pressure (sum values-from turtles [pressure]) / area
  ;ifelse length pressure-history < 1
  ;[ set pressure-history fput total-pressure pressure-history ]
  ;[ set pressure-history fput total-pressure (but-last pressure-history) ]
  ;set avg-pressure mean pressure-history
end

;;; plotting procedures
to setup-plots
  set-current-plot "Speed"
  set-plot-y-range 0 ceiling (number / 6)
end

to do-plotting
  set-current-plot "Speed"
  set-current-plot-pen "fast"
  plot fast
  set-current-plot-pen "average"
  plot average
  set-current-plot-pen "slow"
  plot slow
  
  set-current-plot "Temperature vs Time"
  set-current-plot-pen "temperature"
  plot avg-energy

  set-current-plot "Pressure vs Time"
  set-current-plot-pen "pressure"
  plot total-pressure
  
  set-current-plot "Volume vs Time" 
  set-current-plot-pen "volume"
  plot volume
      
  set-current-plot "Outside vs Inside Temperature"
  set-current-plot-pen "outside"
  plot outside-temperature
  set-current-plot-pen "inside"
  plot avg-energy
end

;;histogram procedures
to do-histograms
  if (histogram?)
    [ histo-energy ]
end

to histo-energy
  set-current-plot "Energy histogram"
  set-current-plot-pen "fast"
  histogram-from turtles with [color = red] [ energy ]
  set-current-plot-pen "medium"
  histogram-from turtles with [color = green] [ energy ]
  set-current-plot-pen "slow"
  histogram-from turtles with [color = blue] [ energy ]
  set-current-plot-pen "avg-energy"
  plot-pen-reset
  draw-vert-line avg-energy
end

;; histogram procedure
to draw-vert-line [ xval ]
  plotxy xval plot-y-min
  plot-pen-down
  plotxy xval plot-y-max
  plot-pen-up
end


; *** NetLogo Model Copyright Notice ***
;
; This activity and associated models and materials were created as part of the project:
; MODELING ACROSS THE CURRICULUM.  The project gratefully acknowledges the support of the 
; National Science Foundation, National Institute of Health and the Department of Education 
; (IERI program) -- grant number REC # 0115699. Additional support was provided through the 
; project: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS 
; -- NSF (REPP program) -- grant number REC #9814682.
;
; Copyright 2002 by Uri Wilensky.  Updated 2002.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2003).  NetLogo GasLab Heat Box model.
; http://ccl.northwestern.edu/netlogo/models/GasLabHeatBox.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/GasLabHeatBox
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
386
24
680
339
35
35
4.0
0
10
1
1
1

CC-WINDOW
367
366
691
493
Command Center

BUTTON
20
42
101
75
NIL
setup
NIL
1
T
OBSERVER
T

BUTTON
20
83
101
116
NIL
go
T
1
T
OBSERVER
NIL

SLIDER
109
42
317
75
number
number
0
500
207
1
1
particles

MONITOR
131
232
238
281
NIL
clock
0
1

MONITOR
23
555
103
604
NIL
avg-speed
3
1

MONITOR
241
136
363
185
inside-temperature
avg-energy
3
1

MONITOR
9
232
122
281
volume
volume
3
1

MONITOR
241
185
363
234
inside-pressure
total-pressure
3
1

SLIDER
7
151
238
184
outside-temperature
outside-temperature
0
500.0
42.0
1
1
NIL

SWITCH
108
82
247
115
wall-is-locked?
wall-is-locked?
1
1
-1000

SLIDER
7
185
238
218
outside-pressure
outside-pressure
1
20.0
2.0
1
1
NIL

PLOT
112
506
356
664
Speed
time
count
0.0
100.0
0.0
200.0
true
true
PENS
"fast" 1.0 0 -65536 true
"average" 1.0 0 -11352576 true
"slow" 1.0 0 -16776961 true

PLOT
24
306
329
492
Outside vs Inside Temperature
time
temperature
0.0
500.0
0.0
500.0
true
true
PENS
"outside" 1.0 0 -16776961 true
"inside" 1.0 0 -6524078 true

PLOT
370
504
600
663
Energy histogram
Energy
Number
0.0
500.0
0.0
10.0
true
false
PENS
"fast" 10.0 1 -65536 true
"medium" 10.0 1 -11352576 true
"slow" 10.0 1 -16776961 true
"avg-energy" 1.0 0 -7566196 true

SWITCH
620
563
747
596
histogram?
histogram?
0
1
-1000

PLOT
697
42
933
203
Temperature vs Time
time
temperature
0.0
100.0
0.0
100.0
true
true
PENS
"temperature" 1.0 0 -65281 true

PLOT
697
204
933
354
Pressure vs Time
time
pressure
0.0
100.0
0.0
10.0
true
true
PENS
"pressure" 1.0 0 -44544 true

PLOT
697
355
932
505
Volume vs Time
Time
Volume
0.0
100.0
0.0
100.0
true
true
PENS
"volume" 1.0 0 -16777216 true

@#$#@#$#@
WHAT IS IT?
-----------
This model is illustrating the relationship between pressure, volume, temperature and number of particles as noted in the (PV = nRT) equation of the Ideal Gas Laws. (P=pressure, V=volume, n=number of particles, R=constant value, T=temperature)

A constant number of particles are trapped within a box that can change its volume. As the walls of the box are heated, the sides of the walls will change color from a deep red (cool) to a bright red, to pink to a pale pink white (hot).  The walls contain a constant heat value throughout the simulation. The gray wall is movable if the WALL-IS-LOCKED? switch is off.   When this switch is off, competing pressures (inside and outside pressures) move the wall.  If the pressure on the inside of the box is greater than the pressure on the outside of the box, then the wall will move to the right, increasing the volume of the box.  But if the pressure on the outside is greater than the pressure on the inside, then the wall will move to the left, decreasing the volume of the box.

When the wall lock is on volume and numbers of particles are being held constant to illustrate the relationship between pressure and temperature.  When the wall lock is off and the wall is able to move freely, pressure and number of particles are held constant to illustrate the relationship between volume and temperature.

The particles are modeled as single particles, all with the same mass and initial velocity.  Molecules are modeled as perfectly elastic particles with no internal energy except that which is due to their motion.  Collisions between molecules are elastic.  Particles are colored according to speed -- blue for slow, green for medium, and red for high speeds.  

In this model, pressure is calculated by adding up the momentum transferred to the walls of the box by the particles when they bounce off the wall.  This is averaged over all of the walls and recorded as the pressure.  When the OUTSIDE-TEMPERATURE slider is increased, this increases the temperature of the walls.  The increase in temperature of the walls will directly affect the behavior of the particles.  As the particles hit the walls, they will conduct heat from the walls increasing their speed.  This increase in speed, increases the chance of hitting the walls more often.  Since the average number of total collisions between the particles and the walls measures pressure, faster particles will result in an increase in pressure.  If the wall is not locked and the pressure on the inside of the box exceeds the pressure on the outside of the box, the wall will move.  When the volume increases, the number of collisions between the particles and walls decreases which lowers the pressure and sometimes the wall will move, decreasing the volume of the box.   

The Heat Box models are one in a collection of GasLab models that uses the same basic rules for expressing what happens when particles collide. Each of the GasLab models has different features to show the different aspects of the Gas Laws.

Adaptations of this model can be found in the Chemistry folder of the Curricular Models section under the name Chem Heat Box.  This model is part of a suite of models used to teach students about the Gas Laws from a chemistry prospective.


HOW IT WORKS
-------------
The exact way two particles collide is as follows:
1. Two turtles "collide" when they find themselves on the same patch.
2. A random axis is chosen, as if they were two billiard balls that hit and this axis was the line connecting their centers.
3. They exchange momentum and energy along that axis, according to the conservation of momentum and energy.  This calculation is done in the center mass system.
4. Each turtle is assigned its new speed, energy and heading.
5. If a turtle finds itself on or very close to a wall of the container, it "bounces" -- that is, reflects its direction but exchanges energy with the wall if they're different.

The exact way particles gain energy from the walls of the box is as follows:
1. Particles check their state of energy.
2. They hit or bounce off the wall.
3. They find wall energy and recalculate their new energy.
4. They change their speed and direction after the collision.


HOW TO USE IT
-------------
Buttons:
  SETUP - sets up the model with the current values of the sliders and switch
  GO - runs the model

Sliders:
  NUMBER - number of particles within in the box
  OUTSIDE-TEMPERATURE - temperature of the outside of the box and the wall of the box
  OUTSIDE-PRESSURE - the outside pressure put on the wall (pressure to the right of the wall)

Switch:
  WALL-IS-LOCKED? - Determines if the wall is locked in place or moving

Plots:
  PRESSURE VS. TIME - average pressure of the inside of the box over time
  VOLUME VS. TIME - volume of the box over time
  TEMPERATURE VS. TIME - average particle temperature inside the box over time 
  OUTSIDE VS. INSIDE TEMPERATURE - average particle temperature and  wall temperature over time
  SPEED VS. TIME - plots the speeds of the particles over time
  ENERGY HISTOGRAM - illustrates the number of particles at their various energy levels
  
Adjust the NUMBER, WALL-IS-LOCKED?, OUTSIDE-TEMPERATURE, OUTSIDE-PRESSURE variables before pressing SETUP.  The SETUP button will set the initial conditions.  The GO button will run the simulation.  

In this model, though, the collisions of the piston with the particles are ignored. Note that there's a physical impossibility in the model here: in real life if you moved the piston down you would do work on the gas by compressing it, and its temperature would increase.  In this model the energy and temperature are constant no matter how you manipulate the piston.  Nonetheless, the basic relationship between volume and pressure is correctly demonstrated here.


THINGS TO NOTICE
----------------
What happens to the wall when the inside pressure is greater than the outside pressure?

What happens to the wall when the outside pressure is greater than the inside pressure?

How does locking the wall and not locking the wall affect pressure?

How does the volume of the box change as the outside pressure increases? Decrease?    
  
How can the relationship between pressure and volume be explained in terms of the collisions of molecules?

How does adding heat to the box walls affect the pressure with volume constant? With the volume variable?

How does adding heat to the wall affect the particle behavior?


THINGS TO TRY
-------------
Determine the conditions needed to have the wall sit to the far right of the box? Far left of the box?

Try to get the pressure on either side of the wall to equalize.  Try to get the wall to not bounce.

Try to get the wall to equalize in the middle of the box.


EXTENDING THE MODEL
-------------------
Give the wall a mass and see how that affects the behavior of the model.

Close off the right side of the box.  Create two values on either side to the wall that allow the user to "spurt" particles into the chambers to see how number of particles affects pressure.


NETLOGO FEATURES
----------------  
Notice how the collisions are detected by the turtles and how the code guarantees the same two particles do not collide twice.  What happens if we let the patches detect them?
 

CREDITS AND REFERENCES
----------------------
To refer to this model in academic publications, please use: Wilensky, U. (2003).  NetLogo GasLab Heat Box model. http://ccl.northwestern.edu/netlogo/models/GasLabHeatBox. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use: Copyright 2003 by Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/GasLabHeatBox for terms of use.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0beta5
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@