globals 
[
  time-to-stop?   ;; boolean that discontinues run when columns reach to top
  messenger       ;; holds identity of the single turtle of breed 'messengers'
                  ;; (see EXTENDING THE MODEL)
  max-y-histogram ;; how high the columns can rise (or how far up the yellow goes)
] 

breeds 
[
  column-counters ;; they keep track of their respective histogram columns
  frames          ;; square frames that indicate events in histogram columns
  messengers      ;; carry the random value to its column
                  ;; (currently just one single messenger implemented)
]

column-counters-own 
[
  ;; if you choose a sample-space 7 then you get 7 column-counters 
  ;; and their respective my-columns will be 1 thru 7
  my-column
  ;; each column-counter holds all patches that are in its column as an agentset
  my-column-patches
]

to setup
  ca
  ;; computes the height the user has requested so as to get the value that makes sense
  ;; in this model becasue the histogram grows from the negative-y values and not from 0
  set max-y-histogram ((- screen-edge-y) + height)
  create-histogram-width   
  create-column-counters
  set time-to-stop? false
end

to create-histogram-width
  ask patches
  [
    ;; deals with both even and odd sample-spaces 
    ;; this is one way of centering the histogram.
    ;; that means that the '50' of the red-green slider
    ;; will always be aligned with the middle of the histogram
    ifelse (pxcor >= (- sample-space) / 2) and (pxcor < sample-space / 2) 
            and (pycor < max-y-histogram) ;; this shapes the top of the yellow zone
    [ set pcolor yellow ]
    [ set pcolor brown ]
  ]
end

    ;; column-counters are turtles who form "place-holders" so that 
    ;; the messenger will "know" where to take its value.
    ;; they are like the values on the x-axis of your sample space. 
to create-column-counters
  ask patches with [(pycor = (- screen-edge-y)) ;; bottom of the screen
                       and pcolor = yellow]      ;; and in the histogram band width
  [
    sprout 1
    [
      set breed column-counters
      ht  ;; it is nice to see them but probably visually redundant
      set heading 0
      ;; this assigns a column name to column-counters that 
      ;; corresponds with the parameter setting of sample-space 
      set my-column floor (pxcor + sample-space / 2 + 1)
      set my-column-patches patches with [ pxcor = pxcor-of myself ]
    ]
  ]

end

to go ;; forever button  
  if time-to-stop? [ stop ]
  select-random-value
  if pause-at-top? [ wait 0.5 ]
  send-messenger-to-its-column
  ifelse colors? 
  [ paint ]
  [ ask patches [ set pcolor yellow ]]   
end

    ;; 'messenger' is a turtle who carries the random value
    ;; on its back as a label
to select-random-value
  ask patch 0 (max-y-histogram + 4) 
  [
    sprout 1 
    [
      set breed messengers
      set shape "default"
      set color black
      set heading 180
      set size 12
      set label 1 + random sample-space
      ;; currently there is just one messenger, so we assign it to a 'messenger'
      ;; variable. this will save time when the model run. if the user chooses
      ;; to add more messengers then this shortcut may have to be done away with
      set messenger self
    ]
  ]
end

    ;; messenger is the dart-shaped large turtle that carries the random value
    ;; on its back. it takes this value directly to the appropriate column
to send-messenger-to-its-column
  locals [ it ] ;; 'it' holds the column-counter who is master of the 
                ;; column towards which the messenger orients and advances
                ;; to dispatch its event
  set it one-of column-counters with [ my-column = label-of messenger ] 

  ask messenger  
  [
    set heading towards-nowrap it
    ;; keep advancing until you're all but covering your destination
    while [ distance-nowrap it > 3 ]
    [
      fd 2 ;; to the patch above you to prepare for next event
      display
    ]
    die
  ]
  ask it  
  [ create-frame 
    fd 1
    ;; if the histogram has become too high, we just stop.
    ;; this could be extended so as to have the whole population
    ;; of events collapse down one patch, as in Galton Box
    if ycor = max-y-histogram [ set time-to-stop? true ]
  ]
    
end

;; make the square frames that look like accumulating cubes
to create-frame ;; turtle procedure
  ask patch-here
  [
    sprout 1 
    [ 
      set breed frames
      set shape "frame"
      set color black 
    ]  
  ]
end

    ;; patches are red if they are as far to the right within the sample-space 
    ;; as indexed by the red-green slider; otherwise, the are green
    ;; Note that currently there is no rounding -- just a cut-off contour.
to paint
  ask column-counters
  [
    ifelse my-column <= (red-green * sample-space / 100)
    [ ask my-column-patches with [ pycor < pycor-of myself ] [ set pcolor red ] ] 
    [ ask my-column-patches with [ pycor < pycor-of myself ] [ set pcolor green ] ] 
  ]
end

;; reports the percentage of red patches out of all patches that have frames
;; so we know what percent of events are to the left of the cut off line
to-report %-red
  report precision (100 * count patches with [pcolor = red] / count frames)
                   2
end

;; biggest-gap is the greatest difference in height between all columns
to-report biggest-gap
  locals [max-column min-column]
  set max-column max values-from column-counters
                       [count my-column-patches with [pycor < pycor-of myself] ]
  set min-column min values-from column-counters
                       [count my-column-patches with [pycor < pycor-of myself] ]
  report max-column - min-column
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
;
; Copyright 2002 by Uri Wilensky.  Updated 2003.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2002).  NetLogo Random Basic model.
; http://ccl.northwestern.edu/netlogo/models/Random Basic.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/Random Basic
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
177
10
894
468
50
30
7.0
1
10
1
1
1

CC-WINDOW
168
507
895
597
Command Center

SLIDER
173
469
890
502
red-green
red-green
0
100
50
1
1
NIL

BUTTON
55
87
118
120
NIL
Setup
NIL
1
T
OBSERVER
T

BUTTON
55
124
118
157
NIL
Go
T
1
T
OBSERVER
T

SWITCH
45
430
135
463
colors?
colors?
0
1
-1000

MONITOR
44
376
136
425
%-red
%-red
3
1

MONITOR
44
254
136
303
total trials
count frames
3
1

SLIDER
2
17
174
50
sample-space
sample-space
1
100
100
1
1
NIL

MONITOR
44
314
136
363
biggest gap
biggest-gap
3
1

SLIDER
2
51
174
84
height
height
1
50
50
1
1
NIL

SWITCH
16
162
162
195
pause-at-top?
pause-at-top?
0
1
-1000

@#$#@#$#@
WHAT IS IT?
-----------
Random Basic is the simplest of all the Problab models. It can either be used first or as a detour from a more complex model to explain randomness.

This model introduces the user to the random generator in NetLogo. Randomness means that in the short term you cannot guess a value but in the long term all possible values will have occurred equally often, more or less.

Here we see a histogram grow reflecting a real-time succession of random events. You can think of the histogram as a competition between the columns and ask whether one of the columns wins more often than others. Or you can think of it as some goodies being given out and think about whether the goodies are being given out fairly. Or think about it some other way -- that's fine.

You can set the size of the sample space. Also, you can monitor how the running time and size of the sample-space affects variability in distribution by partitioning the sample space. 


HOW IT WORKS
------------
At every tick, the computer selects a random value. Just what this means is what the model is all about. You will get this as you work with the model. This random value piggy-backs on a virtual creature that looks like a dart. In this program the creature is called the 'messenger' because over and over it takes the value across the screen to the column that fits its current number. Once it gets to its column, it vanishes but the column becomes taller by one square (the squares are called 'frames' in this and other models in ProbLab). The columns keep growing until one of them has reached pretty high in the graphics window (where the yellow ends) and stops the run.


HOW TO USE IT
-------------
Choose a sample-space (you can leave it at the default value of '100') and press Setup. Now press Go. The messenger (the dart-like creature) will select random values and "take" them over to their columns. The red-green slider sets which columns have red patches and which have green. If it's set at 50% and if the sample space is 100 then patches up to 50 will be red and the rest will be green. If it's set at 50% and the sample space is 30 then patches up to 15 will be red. There are cases where this might be confusing: For instance, if it's set at 50% and if the sample space is 5 then patches up to 2 will be red. Why is that? The '3'-column will be green because it goes further than 50% of 5.  That is, all columns up to and including the 3-column are more than 50% of the columns in the sample-space of 5 -- they are actually 60% because each of the 5 columns makes up 20% (and 5 * 20% is 100%). (See the section EXTENDING THE MODEL, below.)

These are the widgets on the screen in their order of appearance from top to bottom:
SAMPLE-SPACE is a slider for setting how many columns you want to be filling up. Also, it sets the range of numbers that will be randomly selected. If you set the slider to 3 then you will have 3 columns and the values will always be either 1, 2, or 3.
SETUP - prepares the model for running with your sample-space parameter setting.
GO - runs the model with the current settings.
PAUSE-AT-TOP? - when on, the messenger will wait a brief moment before pointing and going down. When off, there will be no delay.
TOTAL-TRIALS - shows how many times the values have been randomly selected. That is, how many times the messenger has dispatched his values.
BIGGEST GAP - shows the biggest vertical difference between all columns. For instance, if the highest column is 10 squares high and the lowest is at 3 squares high then this monitor will show '7'.
%-RED - shows what percentage of the squares are red out of all the squares.
COLORS? - when this switch is on the patches get painted either red or green depending on the red-green slider value and their position.
RED-GREEN - sets the cut-off line for which patches are painted red and which green. When your sample-space is 100 then the position of the little handle on the slider (what you grab and move) is exactly at the cut-off line. For sample spaces other than 100 it will be under the cut-off line only when it is set at 50. This is because currently this slider works according to percentage of events and not column value.


THINGS TO NOTICE
----------------
Each random number can be thought of as an 'event' in your experiment. If the events were not random then they would follow some rule, for instance 1, 2, 3, 4, etc. But random means that at any moment it could be any one of the values from the sample space. If the sample space is set to 100, say, then your first events could be 34, 71, 50, 99, 71, 9, etc. That is, they could be "whatever." So what does that mean if you run the model for some time. Try to form some kind of sense of what's going on.

What happens to the biggest gap as the model runs. Does it change? Does it get consistently bigger? Smaller? Is this connected to the size of the sample space or not? Try to come up with an explanation for this. Also, if you keep running the model with the same sample space until it stops, are you getting the same biggest gap each time? Is it "kind of the same"?


THINGS TO TRY
-------------
How does the size of the Sample-Space affect your sense of "fairness?" Is it more "fair" when the sample-space is small (narrow) or when it is big (wide)? Try different Sample-Spaces and see if you feel that the events are being equally distributed across the histogram. You can set the red-green slider at 50%, then at other values, and, looking at the %-red monitor, evaluate how long it takes for the red-green and the %-red values to be more or less the same. Perhaps a good way to go about this is by using a sample-space of size 2. This is kind of like flipping a coin, right? Or you could set it to a sample-space of 6. This is kind of like rolling a die, right?

Actually, what is fairness? If the difference between two columns is 3 is that the same in the case that one has 0 and the other has 3 as compared to the case where one has 20 and the other has 23?

How does the passage of time -- more and more events -- affect how close the red-green slider and the %-red are?

If you build a sample space of size 6 and run the model, does this remind you of anything? Think of a die. That has 6 sides, right? Can you make connections here?

Use the red dart icon over the graphics window to turn turtles shapes on and off. This will show you the distributing in a slightly different way. To me it looks like a random shower building a city skyline! 


EXTENDING THE MODEL
-------------------
There are many things to look at when dealing with randomness. Currently, the red-green slider shows you how many patches there are that are smaller than a cut-off value. But you may want to know, for instance, how often the value '1' appeared and compare it to how many times the value '2' appeared. You could just count, but you may want to compare the ratio between these accumulations and see what happens to it as the program runs. 

Another idea is to keep track of how many times, on average, a certain value, for instance '1' occurs out of every 10 trials. That's called taking a sample.

Yet another idea is to keep track of how long it takes, on average, until you get a certain value, for instance '1.' That's called 'waiting time.

Even another thing to check is how often you get a "double," that is, how often you get the same value back to back. How would the sample size affect that?

For every one of these ideas and for your own ideas you may want to build plots.

Currently we have a monitor that shows the biggest gap. Try to implement a monitor that shows the smallest gap.

The red-green slider to work differently. For instance, instead of indexing the percentage, it could index the column number. For instance, if the red-green were set to 7 then it could index all the columns from 1 through 7. There are advantages and disadvantages to such a technique. See what fits your needs best. 

Currently, there is only one messenger. What would happen if you added more messengers? Perhaps you could sprout them at different locations on the screen and have them execute the same code. Would this change the way the type of experimental outcomes?

Add a slider that allows you to choose specific columns and find out how many squares have accumulated in it.

Perhaps you noticed that each time you setup and run the model (each experiment) the random numbers come in a different order. But you may want to explore the same set of random numbers in several experiments where you modify some parameters. To do this, you should try working with the NetLogo primitive "random-seed number." You may have challenges getting this primitive to give you what you need if you keep changing the size of the sample space. 


NETLOGO FEATURES
----------------
We use the 'random' primitive a great deal in NetLogo and especially in ProbLab, where we care about probability. But how does NetLogo produce random numbers? Does it roll a die or flip a coin? Actually, NetLogo uses the "Mersenne Twister" random generator. This generator is sometimes called a 'pseudo-random' generator because it is not based on the structure or behavior of a physical mechanism, such as a coin. Rather, it uses a certain mathematical algorithm to produce numbers that appear random, but are actually predictable. That's how one can get identical output sequences of random numbers if one initially feeds in the same seed on subsequent runs: because the recursive algorithm is entirely deterministic.


RELATED MODELS
--------------
See the ProbLab models, that all use randomness. Having worked with this model, you may now have a better sense of where these random numbers are coming from and what to expect when the random primitive is used. In particular note how in the other models we will be looking at how randomness can be evaluated when it is expressed in behaviors of creature on your screen. 


CREDITS AND REFERENCES
----------------------
Thanks to Dor Abrahamson for his work on the design of this model and the ProbLab curriculum.

To refer to this model in academic publications, please use: Wilensky, U. (2002). NetLogo Random Basic model. http://ccl.northwestern.edu/netlogo/models/RandomBasic. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use: Copyright 2002 by Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/RandomBasic for terms of use.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

frame
false
0
Rectangle -16777216 true false -1 1 15 301
Rectangle -16777216 true false 1 -5 303 16
Rectangle -16777216 true false 285 0 315 305
Rectangle -16777216 true false 0 285 297 299
Rectangle -16777216 true false 13 10 30 292
Rectangle -16777216 true false 9 31 11 32
Rectangle -16777216 true false 16 8 293 30
Rectangle -16777216 true false 270 23 299 292
Rectangle -16777216 true false 14 273 15 274
Rectangle -16777216 true false 15 272 16 272
Rectangle -16777216 true false 15 271 290 289

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0beta5
@#$#@#$#@
setup
repeat 50 [ go ]
select-random-value
; we're going to abuse the max-y-histogram variable now because
; we can't introduce our own local variable here
set max-y-histogram one-of column-counters with [my-column = label-of messenger]
ask messenger  
  [
    set heading towards-nowrap max-y-histogram
    ;; keep advancing until you're all but covering your destination
    while [ distance-nowrap max-y-histogram > 10 ]
    [
      fd 2
    ]
  ]
@#$#@#$#@
@#$#@#$#@