globals [target-color other-color background-color patches-in-block %-target-color-list]
patches-own [my-color]
breeds [frames]

to startup
    initialize
    chequer    
end

to initialize
    ca
    set-colors
    set %-target-color-list []
    set patches-in-block []
end

;; We used color variables and not just colors so that you could change the color values
;; to suit you. For instance, perhaps you would want to change the green to cyan
to set-colors
    set target-color red
    set other-color green
    set background-color 44
end

;; This procedure starts the graphics window with a checkered display.  
;; This procedure's function is (a) to give the user a sense of the layout of the land 
;; (b) aesthetic. You can copy this basic code to your own models. 
to chequer
    ask patches 
    [
     ifelse  ( ( pxcor / 2  = int (pxcor / 2) ) and ( pycor / 2  = int (pycor / 2) ) ) or 
             ( ( pxcor / 2 != int (pxcor / 2) ) and ( pycor / 2 != int (pycor / 2) ) )
     
     [set pcolor target-color]
     [set pcolor other-color]
    ]
end

to setup 
    initialize  
    create-block
    create-frames
end

to create-block ;; creates in the graphics window a red block of all patches-in-block
    ask patch 0 0
      [set patches-in-block ( in-rectangle patches ((block-side - 1) / 2)
                                                   ((block-side - 1) / 2) ) ]
    ask patches [set pcolor brown]
    ask patches-in-block [set pcolor background-color]
end

;; report the agentset within a box that has a width = (width/2 * 2) + 1
;; and a height = (height/2 * 2) + 1 and is centered on the calling agent
to-report in-rectangle [patchset width/2 height/2]
  report patchset with
  [
    pxcor <= (pxcor-of myself + width/2) and pxcor >= (pxcor-of myself - width/2) and
    pycor <= (pycor-of myself + height/2) and pycor >= (pycor-of myself - height/2)
  ]
end

to create-frames ;; each individual patch in the block is framed, creating an overall effect  
                 ;; of a grid that helps distinguish individual patches in the block
    set-default-shape frames "frame"
    ask patches-in-block
    [
      sprout 1 
      [ set breed frames
        set color black ]  
    ]
end

to go
    if target-color = 0 [stop]
    ask patches-in-block
    [
      ifelse random-float 100 < %-target-color
        [set pcolor target-color ] [set pcolor other-color]
    ]
    
    ;; We multiply by 100 in order to convert a probability, e.g., .23, into a percent -- 23.
    set %-target-color-list fput ( 100 * ( count patches-in-block with [pcolor = target-color] )
                                   / count patches-in-block )
                                 %-target-color-list
    plot-color-distribution
end

to plot-color-distribution
    set-current-plot "Color Distribution"
    set-current-plot-pen "%-target-color"
    histogram-list %-target-color-list
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
;
; Copyright 2002 by Uri Wilensky.  Updated 2003.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2002).  NetLogo Stochastic Patchwork model.
; http://ccl.northwestern.edu/netlogo/models/StochasticPatchwork.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/StochasticPatchwork
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
329
10
675
377
10
10
16.0
1
10
1
1
1

CC-WINDOW
28
433
675
528
Command Center

SLIDER
29
62
316
95
block-side
block-side
1
17
7
2
1
NIL

SLIDER
53
343
291
376
%-target-color
%-target-color
0
100
50
1
1
%

BUTTON
29
11
92
58
Setup
setup
NIL
1
T
OBSERVER
T

BUTTON
253
10
316
59
Go
go
T
1
T
OBSERVER
T

MONITOR
131
107
224
156
# target color
count patches-in-block with [pcolor = target-color]
3
1

PLOT
34
173
317
342
color distribution
% target color
occurrences
0.0
100.0
0.0
10.0
true
false
PENS
"%-target-color" 0.0010 1 -65536 true

@#$#@#$#@
WHAT IS IT?
-----------
This model is a part of the ProbLab curriculum. The ProbLab Curriculum is currently under development at the CCL. For more information about the ProbLab Curriculum please refer to http://ccl.northwestern.edu/curriculum/ProbLab/.

The longer name of Stochastic Patchwork is Agent-Aggregate Probability Distribution. It is a simple model for thinking about Probability. Specifically, the user can study the relation between, on the one hand, individual agents' probability to have one of two values in the dichotomous variable color, and on the other hand, the aggregate or overall distribution of these values within a population of such patches. Moreover, by collecting these momentary aggregate probabilities and plotting them in a "growing" histogram, the probability distribution becomes a dynamic model of stochastic behavior.

Thus, the model objectifies, problematizes, and elaborates the complementarity of agent-based and aggregate perspectives on probability distribution. 


HOW IT WORKS
------------
At every iteration through Go, each patch "rolls a die" to decide whether it should be red or green. This "die" works as follows: The patch chooses a random number between 0 and 100. Next, the patch checks to see whether this number is smaller or larger than the value you set on the "%-target-color" slider. If, for instance, the random number was 29 and the slider value was 25, then the patch will become red, but if -- say on the immediately consecutive iteration through Go -- the random number happened to be 15 (and you have not changed the slider value from 25) then the patch will be green on this iteration. At every iteration through Go, the overall value of the population's "red-ness" is calculated as the number of red patches in the block divided by the total number of patches in the block. This calculated value is added to a growing list that thus grows in length from iteration to iteration. The entire list is plotted as a histogram at each iteration.

Over many iterations, the histogram begins to form a bell-curve shape with your chosen %-target-color as a mean (and mode and median).


HOW TO USE IT
-------------
Buttons:
'Setup; - prepares the size of population according to the block-side slider value.
'Go'  - activates the procedures. It is set to work "forever," that is, repeatedly until you press it again.

Sliders:
'block-side' - the larger the value you set here, the larger the size of your square population. If the block-side is X, then the block will be of dimensions X^2. For example, a block-side of 3 will give a population of 9 square patches.
'%-target-color' - Use this slider to control the average probability that each patch will be red in each iteration through Go.

Monitors:
'# target color' - shows how many patches in the block are red. (Note that the plot window shows a histogram of the percent red, and not of the number of red patches.)

Set the sliders to the values of your choice, press Setup, and then press Go.


THINGS TO NOTICE
----------------
The larger your block, there are more different overall outcomes, so the histogram becomes denser. For instance, for a population of 9 patches (block-side = 3) there are 9 different outcomes: 1 out of 9 are red, 2 out of 9 are red, 3/9 are red, 4/9, 5/9, 6/9, 7/9, 8/9, and 9/9. But for a population of 25 patches (block-side = 5) there are 25 different outcomes: 1/25, 2/25...24/25, 25/25. Try running the model under block-side 3 and then 5 to appreciate this difference. Interestingly, if you were working with a line graph and not a histogram, you would never see this difference. To try this, you can edit the graph by selecting it and clicking on it. Now change the plot pen's mode from 'Bar' to 'Line,' and run the model again. Another way to notice the difference between small and large populations is to see how many different outcomes are accumulating into the list of all outcomes. Run the model with a block-side 3 for about 10 seconds, and then, in the command center, write "show %-target-color-list." Notice how there are 9 different outcomes. You can also type in: 
|          show length remove-duplicates %-target-color-list 
This will report the number of different outcomes in the list. Compare this to a population of block-side 5.


THINGS TO TRY
-------------
OK, so we know that a population of 9 squares gives 9 different outcomes (see previous section). But what happens if you change the %-target-color value? Surely that should change the number of outcomes! Or does it?... Under what conditions of operating the model would this change the size of the sample space (number of different types of outcomes) and under what conditions would this not affect the sample space?

How long does it take for the histogram to start taking its typical bell shape? How is this duration of time related, if at all, to the size of the population?

How is the shape of the curve related to the %-target-color value? Choose a largish block-side value, then set the %-target-color slider to an extremely high value, such as 98%. Let the model run until it begins to take some distinctive shape. Now, stop the model by pressing the Go button again. Then, without pressing Setup, re-set the %-target-color slider to, say, 70% and let it run again. Repeat this several times for smaller and smaller percentages, ending with another extreme percentage, say 2%. You will have a set of curves on your screen. Are they all bell shaped? -- If not, why not?

Ask a friend to set up the %-target-color value for you without your looking. Now, cover the left-hand side of the screen (so that you see only the graphics window). You can also do that by asking your friend to shift the entire NetLogo window to the left so that the left-hand side of the window is hidden off screen. Next, run the model (or have your friend run it and only then hide it). Looking at the flashing colors on the population block, try to guess the percentage of red. Practice this, then switch roles with your friend. Who is better at this task? Discuss your strategies. (see 'Experts' in the EXTENDING section.) 


NETLOGO FEATURES
----------------
Look in the code at the procedure 'to create-block' and the reporter procedure 'in-rectangle' immediately below it. Note how adjustments need to be made in order to get the code to produce a block of patches with the 'block-side' the user sets. You may wish to familiarize yourself with what might seem at first confusing: Even though the patches create a grid-like structure, this grid is offset from the underlying coordinate system that gives patches their names. This real coordinate system runs through the patches' centers and not along their perimeters. For instance, the location of "patch 0 0" is precisely that -- [0 0] -- because its center, that is, its pxcor and pycor, is on the origin. But in fact, the patch 0 0 extends from -0.5 to +0.5 along both the x and the y axes. 


EXTENDING THE MODEL
-------------------
A first jab at coding is to change the two focal colors from red and green to whatever you like. In the Procedures tab, find the "set-colors" procedures and replace the existing colors with others. You may wish to consult the NetLogo manual (in the "Help" drop-down menu) to find out which colors can be named and which have to be numbered.

A more advanced intervention is to work with the plot. What other variables could it be interesting to monitor? You can add a monitor that shows the average probability, or of the occurrence of a particular value. You could create another plot that graphs the average probability as it changes over time. What do you expect that graph would look like - initially, later? How, if at all, would the shape of that graph be related to the settings of the slider values?

Experts (continued from above section): Try extending the model so as to be able to improve your guesstimation strategies. You can even create interactive procedures that will enable you to track your friend's and your progress. For instance, you could modify the model to assign random values to the %-target-color slider without showing you the value. Perhaps it is worthwhile to find ways to make your "guesstimations" more precise. What could such techniques be? How are they related to what scientists call "doing statistics"? Finally, what can we learn about our perceptual mechanism (the way our eyes and brain work together) from this exercise? 


CREDITS AND REFERENCES
----------------------
Thanks to Dor Abrahamson for his work on the design of this model and the ProbLab curriculum.

To refer to this model in academic publications, please use: Wilensky, U. (2002). NetLogo Stochastic Patchwork model. http://ccl.northwestern.edu/netlogo/models/StochasticPatchwork. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use: Copyright 2002 by Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/StochasticPatchwork for terms of use.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

frame
false
14
Rectangle -16777216 true true -8 2 18 298
Rectangle -16777216 true true 1 0 300 16
Rectangle -16777216 true true 283 2 299 300
Rectangle -16777216 true true 1 285 300 299

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0beta5
@#$#@#$#@
set block-side 7
setup
go
@#$#@#$#@
@#$#@#$#@