breeds [ lefts rights sums ] 
turtles-own [ yvel-old yvel-new ypos-old ypos-new time ] 
globals [ time-ticks listening-point ]

to setup 
  ca
  set-default-shape turtles "circle"
  ;; Create the turtles that represent the waves
  ;; We need three lines across the screen, so it sets 
  ;; their xcor based on their incrementing turtle id  
  cct-lefts screen-size-x [
        set xcor ( who - screen-edge-x ) 
        set color yellow ]
  cct-rights screen-size-x [  
      set xcor ( who - screen-edge-x ) 
      set color cyan ]
  cct-sums screen-size-x [  
      set xcor ( who - screen-edge-x ) 
      set color red ]

  ;; Initialize all variables to zero.  All of the turtles are stationary.
  set listening-point 0 
  set time-ticks 0
  ask turtles
  [
    set yvel-old  0  
    set ypos-old  0  
    set time  0  
  ]
  
  ;; The ends of the waves are special.  One side drives the wave, while
  ;; the other side anchors the waves- (prevents wrapping)
  ;; First define the driving turtles, which are colored green.  
  ;; Next define the anchor turtles, which are colored blue  
  ask lefts [
    if  ( xcor = screen-edge-x )  [
      set color blue
    ]
    if ( xcor = (- screen-edge-x) ) [
      set color green
    ]
  ]  
  ask rights [ 
    if  ( xcor = (- screen-edge-x) ) [
      set color blue 
    ]
    if ( xcor = screen-edge-x ) [
      set color green
    ]
  ]

  ;; draw the speakers, gray centered line, and listening point
  ask patches [ 
    if pycor = 0 
      [ set pcolor gray ] 
    draw-left-speaker 
    draw-right-speaker
    if ( pxcor = listening-point and pycor > 0 and pycor < 4 )
      [ set pcolor white ]  
  ]

  setup-plot
end


to go
  ;; Increase the model time
  set time-ticks time-ticks + 1
  
  ;; Move all the wave turtles
  ask turtles [
    if  ( color = green ) 
      [ drive-force ]
    if  ( color = yellow or color = cyan ) 
      [ driven-force ]
    if  ( color = blue )  
      [ follow ]
    if  ( color = red )  
      [ interfere ]
  ]
  
  ;; Update the plot  
  if  ( plot? ) [
    get-a-point
    plot-the-point
  ]
  
  ;; Reset the velocities  
  ask turtles [
    set yvel-old yvel-new  
    set ypos-old ypos-new  
  ]
  
  ;; Check if a hide/show switch changed
  show-or-hide
end


to drive-force ;; procedure for green turtles
  set time time + 1
  ifelse (breed = lefts) 
    [ set ypos-new amplitude-left * ( sin (frequency-left * 0.1 * time )) ]
    [ set ypos-new amplitude-right * ( sin (frequency-right * 0.1 * time )) ]
  set ypos-old ypos-new 
  set ycor ypos-new 
end

to driven-force ;; procedure for yellow and cyan turtles
locals [ curr-set ] 
  set yvel-new yvel-old + ( ypos-old-of turtle ( who - 1 ) ) 
                      - ypos-old  +  ( ypos-old-of turtle ( who + 1 ) ) - ypos-old 
  set yvel-new ( ( 1000 - friction ) / 1000 ) * yvel-new 
  set ypos-new ypos-old + yvel-new 
  set ycor ypos-new 
end

to follow ;; procedure for blue turtles
  ifelse ( breed = lefts )
    [ set ypos-new ypos-old-of turtle ( who - 1 ) ]
    [ set ypos-new ypos-old-of turtle ( who + 1 ) ]
  set ycor ypos-new 
end

to interfere ;; procdure for red turtles
  set ypos-new ( ( ypos-new-of turtle ( who - screen-size-x ) ) 
              + ( ypos-new-of turtle ( who - ( 2 * screen-size-x ) ) ) )
  set ycor ypos-new
  ifelse (( abs ypos-new ) <= screen-edge-y) and show-sum? 
    [ showturtle ] 
    [ hideturtle ] 
end

to setup-plot 
  set-current-plot "Speaker amplitude" 
  clear-plot 
  set-current-plot-pen "left"
  set-plot-pen-color yellow 
  set-current-plot-pen "right" 
  set-plot-pen-color cyan 
  set-current-plot-pen "sum" 
  set-plot-pen-color red 
  set-plot-y-range ( ( - amplitude-left ) - amplitude-right ) ( amplitude-left + amplitude-right ) 
  set-plot-x-range 0 250 
  auto-plot-on 
end

to plot-the-point 
  if ((time-ticks mod 200) = 0) 
    [
      ifelse (not show-only-recent-plot?)
        [ set-plot-x-range 0 (time-ticks + 200) ] 
        [ set-plot-x-range (time-ticks - 210) (time-ticks + 210)]
    ]
    
  set-current-plot-pen "left" 
  if show-left? and any? lefts with [ round xcor = listening-point ] 
    [ plotxy time-ticks ypos-new-of random-one-of lefts with [ round xcor = listening-point ] ]
  
  set-current-plot-pen "right"
  if show-right? and any? rights with [ round xcor = listening-point ]
   [ plotxy time-ticks ypos-new-of random-one-of rights with [ round xcor = listening-point ] ]
  
  set-current-plot-pen "sum"
  if show-sum? and any? sums with [ round xcor = listening-point ]
      [ plotxy time-ticks ypos-new-of random-one-of sums with [ round xcor = listening-point  ] ]
end

to get-a-point
  ;; Changes the listening-point if the mouse is down
  if mouse-down? [ 
    ask patches with [ pxcor = listening-point and pycor > 0 and pycor < 4 ]
      [ set pcolor black ]  
    set listening-point round mouse-xcor
    ask patches with [ pxcor = listening-point and pycor > 0 and pycor < 4 ]
      [ set pcolor white ]  
  ] 
end

to draw-right-speaker ;; patch procedure
  if ( pxcor = screen-edge-x ) and ( pycor > ( -0.1 * screen-edge-x ) ) and ( pycor < ( 0.1 * screen-edge-x ) )
  [ 
    set pcolor orange
  ] 
  if ( pxcor = round ( 0.9 * screen-edge-x ) ) and ( pycor > ( -0.2 * screen-edge-x ) ) and ( pycor < ( 0.2 * screen-edge-x ) )
  [ 
    set pcolor orange 
  ] 
end

to draw-left-speaker ;; patch procedure
  if ( pxcor = ( - screen-edge-x ) ) and ( pycor > ( -0.1 * screen-edge-x ) ) and ( pycor < ( 0.1 * screen-edge-x ) ) 
  [ 
    set pcolor orange 
  ] 
  if ( pxcor = round ( - ( 0.9 * screen-edge-x ) ) ) and ( pycor > ( -0.2 * screen-edge-x ) ) and ( pycor < ( 0.2 * screen-edge-x ) ) 
  [ 
    set pcolor orange 
  ]
end

to show-or-hide
    ;; The sums are hidden in the interference procedure because it has the possibility
    ;; of wrapping when the sum amplitudes are too large.
    ifelse show-left?
      [ 
        if any? lefts with [ hidden? ]
          [ ask lefts [ st ] ] 
      ]
      [ 
        if any? lefts with [ not hidden? ]
          [ ask lefts [ ht ] ]
      ]
    
     ifelse show-right?
      [ 
        if any? rights with [ hidden? ]
          [ ask rights [ st ] ] 
      ]
      [ 
        if any? rights with [ not hidden? ]
          [ ask rights [ ht ] ]
      ]
end    

; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky. All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
; Converted from StarLogoT to NetLogo, 2002.  Updated 2002.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo Speakers model.
; http://ccl.northwestern.edu/netlogo/models/Speakers.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/Speakers
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
332
17
746
452
50
50
4.0
1
10
1
1
1

CC-WINDOW
372
448
737
579
Command Center

BUTTON
80
43
154
76
go
go
T
1
T
OBSERVER
T

BUTTON
6
43
80
76
setup
setup
NIL
1
T
OBSERVER
T

SLIDER
10
132
142
165
amplitude-left
amplitude-left
0
50.0
20.0
1
1
NIL

SLIDER
171
44
303
77
friction
friction
0
100.0
0.0
1
1
NIL

SLIDER
10
99
142
132
frequency-left
frequency-left
1
100.0
30.0
1
1
NIL

MONITOR
11
177
108
226
listening-point
listening-point
3
1

SWITCH
207
507
311
540
plot?
plot?
0
1
-1000

PLOT
4
232
306
492
Speaker amplitude
Time
Amplitude
0.0
250.0
-61.0
50.0
false
true
PENS
"left" 1.0 0 -256 true
"right" 1.0 0 -16711681 true
"sum" 1.0 0 -65536 true

SWITCH
6
507
204
540
show-only-recent-plot?
show-only-recent-plot?
0
1
-1000

SWITCH
5
542
117
575
show-left?
show-left?
0
1
-1000

SWITCH
240
542
357
575
show-right?
show-right?
0
1
-1000

SWITCH
118
542
239
575
show-sum?
show-sum?
0
1
-1000

SLIDER
164
99
296
132
frequency-right
frequency-right
0
100.0
30.0
1
1
NIL

SLIDER
164
132
296
165
amplitude-right
amplitude-right
0
50.0
20.0
1
1
NIL

@#$#@#$#@
WHAT IS IT?
-----------
This model simulates sound wave interference. There is one speaker at each end. A sinusoidal signal generator powers each speaker. In the graphics window, the yellow line represents the sound level due to the left speaker, the cyan line represents the sound level due to the right speaker, and the red line represents the sum of the sound levels due to both speakers.


HOW IT WORKS
-------------
Sound effect is due to pressure change spatially and temporally. The waveforms are made up of three lines of turtles. Each turtle acts as it were connected to its neighboring turtles with springs. When neighboring turtles are further away, they exert a stronger force.

When the left end of the sound level goes up, it "pulls up" the turtle to its right, which in turn pulls up the turtle to its right, and so on. In that way, a sound wave moves through the air.

The green turtles (speakers) continue to put more energy into the air. When there is no friction in the air, the waves in the air travel without losing amplitude.


HOW TO USE IT
-------------
Click the SETUP button to set up the system. Then, click GO to turn on the speakers.

The FRICTION slider controls the amount of sound damping in the air. The FREQUENCY slider controls the frequency of the signal generator. The AMPLITUDE slider controls the sound level of the speakers.

There are three buttons to hide each curve and three buttons to show each curve, so that the curves can be observed individually or collectively.

Set the PLOT? switch to on and click anywhere on the horizontal line in the Graphics Window and you will be able to observe the sound level vs. time at the position you selected. The LISTENING-POINT monitor shows the x coordinate of the point.  A white vertical line in the Graphics Window also shows it.  Click on the line to move the LISTENING-POINT to different points on the screen. The SPEAKER AMPLITUDE plot will plot the sound levels at this listening point.

Set the SHOW-ONLY-RECENT-PLOT? switch to on when you want to see only how the wave has looked in the recent past. With the toggle off, you can see the waves over the whole running time of the model.


THINGS TO NOTICE
----------------

How does the pattern of the left speaker wave and the right speaker wave change when you change the FREQUENCY slider? The AMPLITUDE slider?

When two speakers are turned on, the sound level at a certain point at a certain time is the sum of the sound levels produced by the two speakers at that time.  Its pattern may be quite different from either of the speaker sound patterns.


THINGS TO TRY
------------
Change the values on the sliders and observe what happens to the sum of the sound levels -- the red curve.

Try adding friction to see what it does to the waves.

Move the listening-point -- what do you observe in the plot window?

Try to create a "standing wave," in which some points on the lines do not move at all, and plot one of the points to see if the sum there is zero.

Try to create a flat red curve.

Compare the relationship between frequency and wavelength. 

Find a way to measure the speed of the wave such that the relationship, speed = frequency * wavelength, is true.  


EXTENDING THE MODEL
-------------------
Program the red turtles to find the sum of the absolute values of the two waves.

Make it possible to "fix" the waves to zero at some point along the line -- as if this were a string and you put your finger on it.  

Make the waves "reflect" from each end instead of going on. 


NETLOGO FEATURES
-----------------
In order to have three independent waves, three lines of turtles are created -- yellow, then cyan, and then red -- in order from left to right.  Special turtles are created to control the ends of these waves.  One end generates the wave (green) and the other end prevents the wave motion from wrapping (dark blue).  

For this project, it does not make sense for the turtles to "wrap" when they get to the top or bottom of the screen. So the y-position of the turtles is kept in a new variable (YPOS-NEW), and the turtle is hidden if its y-position moves outside the boundary of the screen.  

During each iteration of GO, each turtle looks at its neighbors and calculates a new speed and position accordingly.  The order in which this is done is not obvious, since the turtles are running in parallel.  It's important that the order in which the turtles look at their neighbors doesn't matter.  Therefore temporary variables are created, "ypos-old", and "yvel-old".   Each turtle looks at its neighbors in previous state and updates its own temporary variables "ypos-new" and "yvel-new".   Then all the turtles update their states together.   


A TRUE STORY
------------
A CCL member was asked by an undergraduate student to help her with some physics experiment problems:

The experiment was about wave propagation and interference.  In the experiment, two speakers are put on a straight track one meter apart and facing each other.  The speakers are connected to a 1500 Hz sinusoidal signal generator.  The student is asked to use a microphone to measure the sound level along the track between the two speakers and write down the positions where the microphone readings are a minimum.

The student is asked to explain the results and to determine if the minimum readings should be zero or not.

The results of the experiment show that the average distance between two minimum readings is about one half of the wavelength. The CCL member could not explain the results and determine if the readings should be zero or not.

The ROPE sample model helped him to answer the student. In the rope model, one end of the rope is fixed.  So the model setup is similar to the experiment setup except for the length and the frequency.  The CCL member and the student then worked together to modify the rope model and change the meaning of the y coordinate -- changing it from representing the absolute value of the deflection, because the microphone reading is the root mean square value of the sound level. When they ran the program, they got the experimental results and, more importantly, it became very clear to them why the minimum readings should be zero and the distance between any two minima is one half of the wavelength.

Isn't it amazing that such a simple program can be so helpful?

Try and repeat what the student and CCL member did and answer the physical experiment problems.


CREDITS AND REFERENCES
----------------------
To refer to this model in academic publications, please use: Wilensky, U. (1998). NetLogo Speakers model. http://ccl.northwestern.edu/netlogo/models/Speakers. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use: Copyright 1998 by Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/Speakers for terms of use.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0beta5
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@