globals [
  weeks             ;; Each time tick is called a week.  
  infection-chance  ;; The chance out of 100 that an infected person will pass on
                    ;;   infection during one week of couplehood.
  symptoms-show     ;; How long a person will be infected before symptoms occur 
                    ;;   which may cause the person to get tested.
  slider-check-1    ;; Temporary variables for slider values, so that if sliders
  slider-check-2    ;;   are changed on the fly, the model will notice and
  slider-check-3    ;;   change people's tendencies appropriately.
  slider-check-4 
]

turtles-own [
  infected?          ;; If true, the person is infected.  It may be known or unknown.
  known?             ;; If true, the infection is known (and infected? must also be true). 
  infection-length   ;; How long the person has been infected.
  coupled?           ;; If true, the person is in a sexually active couple.
  couple-length      ;; How long the person has been in a couple.
  ;; the next four values are controlled by sliders
  commitment         ;; How long the person will stay in a couple-relationship.
  coupling-tendency  ;; How likely the person is to join a couple.
  condom-use         ;; The percent chance a person uses protection.
  test-frequency     ;; Number of times a person will get tested per year.
  partner            ;; The person that is our current partner in a couple. 
]

;;;
;;; SETUP PROCEDURES
;;;

to setup
  ca
  setup-globals
  setup-people
  setup-plot
  update-plot
end

to setup-globals
  set weeks 0
  set infection-chance 50    ;; if you have unprotected sex with an infected partner,
                             ;; you have a 50% chance of being infected
  set symptoms-show 200.0    ;; symptoms show up 200 weeks after infection
  set slider-check-1 average-commitment
  set slider-check-2 average-coupling-tendency
  set slider-check-3 average-condom-use
  set slider-check-4 average-test-frequency 
end

;; Create carrying-capacity number of people half are righty and half are lefty 
;;   and some are sick.  Also assigns colors to people with the ASSIGN-COLORS routine.

to setup-people
  cct initial-people
    [ setxy (random-float screen-size-x)
            (random-float screen-size-y)
      set known? false
      set coupled? false
      set partner nobody
      ifelse random 2 = 0
        [ set shape "righty" ]
        [ set shape "lefty" ]
      ;; 2.5% of the people start out infected, but they don't know it
      set infected? (who < initial-people * 0.025)
      if infected?
        [ set infection-length random-float symptoms-show ]
      assign-commitment
      assign-coupling-tendency
      assign-condom-use
      assign-test-frequency
      assign-color ]
end

;; Different people are displayed in 3 different colors depending on health 
;; green is not infected
;; blue is infected but doesn't know it
;; red is infected and knows it

to assign-color  ;; turtle procedure
  ifelse not infected?
    [ set color green ]
    [ ifelse known?
      [ set color red ]
      [ set color blue ] ]
end

;; The following four procedures assign core turtle variables.  They use
;; the helper procedure RANDOM-NEAR so that the turtle variables have an
;; approximately "normal" distribution around the average values set by
;; the sliders.

to assign-commitment  ;; turtle procedure
  set commitment random-near average-commitment
end

to assign-coupling-tendency  ;; turtle procedure
  set coupling-tendency random-near average-coupling-tendency
end

to assign-condom-use  ;; turtle procedure
  set condom-use random-near average-condom-use
end

to assign-test-frequency  ;; turtle procedure
  set test-frequency random-near average-test-frequency
end

to-report random-near [center]  ;; turtle procedure
  locals [result]
  set result 0
  repeat 40
    [ set result (result + random-float center) ]
  report result / 20
end

;;;
;;; GO PROCEDURES
;;;

to go
  if (not any? turtles with [not known?])
    [ stop ]
  check-sliders
  set weeks (weeks + 1)
  ask turtles
    [ if infected?
        [ set infection-length infection-length + 1 ]
      if coupled?
        [ set couple-length couple-length + 1 ] ]
  ask turtles
    [ if not coupled?
        [ move ] ]
  ;; Righties are always the ones to initiate mating.  This is purely
  ;; arbitrary choice which makes the coding easier.
  ask turtles
    [ if not coupled? and shape = "righty" and (random-float 10.0 < coupling-tendency)
        [ couple ] ]
  ask turtles [ uncouple ]
  ask turtles [ infect ]
  ask turtles [ test ]
  ask turtles [ assign-color ]
  update-plot
end

;; Each tick a check is made to see if sliders have been changed.
;; If one has been, the corresponding turtle variable is adjusted

to check-sliders
  if (slider-check-1 != average-commitment)
    [ ask turtles [ assign-commitment ]
      set slider-check-1 average-commitment ]
  if (slider-check-2 != average-coupling-tendency)
    [ ask turtles [ assign-coupling-tendency ]
      set slider-check-2 average-coupling-tendency ]
  if (slider-check-3 != average-condom-use)
    [ ask turtles [ assign-condom-use ]
      set slider-check-3 average-condom-use ]
  if (slider-check-4 != average-test-frequency )
    [ ask turtles [ assign-test-frequency ]
      set slider-check-4 average-test-frequency ]
end

;; People move about at random.

to move  ;; turtle procedure
  rt random-float 360
  fd 1
end

;; People have a chance to couple depending on their tendency to have sex and 
;; if they meet.  To better show that coupling has occurred, the patches below 
;; the couple are grayed.

to couple  ;; turtle procedure -- righties only!
  locals [potential-partner]
  set potential-partner random-one-of (turtles-at -1 0)
                          with [not coupled? and shape = "lefty"]
  if potential-partner != nobody
    [ if random-float 10.0 < coupling-tendency-of potential-partner
        [ without-interruption
            [ set partner potential-partner
              set coupled? true
              set coupled?-of partner true
              set (partner-of partner) self
              setxy pxcor pycor ;; move to center of patch
              ask partner
                [ setxy pxcor pycor ] ;; partner moves to center of patch
              stamp gray
              set pcolor-of (patch-at -1 0) gray ] ] ]
end 

;; If two peoples are together for longer than either person's commitment variable
;; allows, the couple breaks up.

to uncouple  ;; turtle procedure
  if coupled? and (shape = "righty")
    [ if (couple-length > commitment) or
         (couple-length-of partner) > (commitment-of partner)
        [ without-interruption
            [ set coupled? false
              set couple-length 0
              set (couple-length-of partner) 0
              stamp black
              set pcolor-of (patch-at -1 0) black
              set (partner-of partner) nobody
              set (coupled?-of partner) false
              set partner nobody ] ] ]
end

;; Infection can occur if either person is infected, but the infection is unknown.
;; This model assumes that people with known infections will continue to couple, 
;; but will automatically practice safe sex, regardless of their condom-use tendency.
;; Note also that for condom use to occur, both people must want to use one.  If 
;; either person chooses not to use a condom, infection is possible.  Changing the 
;; primitive to AND in the third line will make it such that if either person 
;; wants to use a condom, infection will not occur. 

to infect  ;; turtle procedure
  if coupled? and infected? and not known?
    [ if random-float 11 > condom-use or
         random-float 11 > (condom-use-of partner)
        [ if random-float 100 < infection-chance
            [ set (infected?-of partner) true ] ] ]
end

;; People have a tendency to check out their health status based on a slider value.  
;; This tendency is checked against a random number in this procedure. However, after being infected for 
;; some amount of time called SYMPTOMS-SHOW, there is a 5% chance that the person will 
;; become ill and go to a doctor and be tested even without the tendency to check.

to test  ;; turtle procedure
  if random-float 52 < test-frequency
    [ if infected?
        [ set known? true ] ]
  if infection-length > symptoms-show
    [ if random-float 100 < 5
        [ set known? true ] ] 
end

;;;
;;; PLOTTING PROCEDURES
;;;

to setup-plot
  set-current-plot "Populations"
  set-plot-y-range 0 (initial-people + 50)
end

to update-plot
  set-current-plot "Populations"
  set-current-plot-pen "HIV-"
  plot count turtles with [not infected?] 
  set-current-plot-pen "HIV?"
  plot count turtles with [infected?] - 
       count turtles with [known?]
  set-current-plot-pen "HIV+"
  plot count turtles with [known?]
end

;;;
;;; MONITOR PROCEDURES
;;;

to-report %infected
  ifelse any? turtles
    [ report (count turtles with [infected?] / count turtles) * 100 ]
    [ report 0 ]
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky. All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
; Converted from StarLogoT to NetLogo, 2001.  Updated 2002.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo AIDS model.
; http://ccl.northwestern.edu/netlogo/models/AIDS.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/AIDS
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
362
10
747
416
12
12
15.0
1
10
1
1
1

CC-WINDOW
362
420
738
533
Command Center

BUTTON
4
42
87
75
setup
setup
NIL
1
T
OBSERVER
T

BUTTON
4
76
87
109
go
go
T
1
T
OBSERVER
T

MONITOR
4
116
87
165
%infected
%infected
2
1

MONITOR
4
166
87
215
years
weeks / 52
1
1

SLIDER
90
42
359
75
initial-people
initial-people
50
500
300
1
1
NIL

SLIDER
90
112
359
145
average-commitment
average-commitment
1.0
200.0
50.0
1
1
weeks

SLIDER
90
77
359
110
average-coupling-tendency
average-coupling-tendency
0.0
10.0
5.0
1.0
1
NIL

SLIDER
90
147
359
180
average-condom-use
average-condom-use
0.0
10.0
0.0
1.0
1
NIL

SLIDER
90
182
359
215
average-test-frequency
average-test-frequency
0.0
2
0.0
0.01
1
times/year

PLOT
4
217
359
461
Populations
weeks
people
0.0
52.0
0.0
350.0
true
true
PENS
"HIV-" 1.0 0 -11352576 true
"HIV+" 1.0 0 -65536 true
"HIV?" 1.0 0 -16776961 true

@#$#@#$#@
WHAT IS IT?
-----------
This model simulates the spread of the human immunodeficiency virus (HIV), via sexual transmission, through a small isolated human population.  As is well known now, HIV is spread in a variety of ways of which sexual contact is only one.  HIV can also be spread by needle-sharing among injecting drug-users, through blood transfusions (although this has become very uncommon in countries like the United States in which blood is screened for HIV antibodies), or from HIV-infected women to their babies either before or during birth, or afterwards through breast-feeding.  This model focuses only on the spread of HIV via sexual contact.  It therefore illustrates the effects of certain sexual practices across a population.

The model examines the emergent effects of four aspects of sexual behavior.  The user controls the population's tendency to practice abstinence, the amount of time an average "couple" in the population will stay together, the population's tendency to use condoms, and the population's tendency to get tested for HIV.  Exploration of the first and second variables may illustrate how changes in sexual mores in our society have contributed to increases in the prevalence of sexually transmitted diseases, while exploration of the third and fourth may provide contemporary solutions to the problem. 

By allowing the user to control how often an average individual will choose to be tested, the user can explore an important dimension of HIV's threat to public health.  Because the virus does not make itself immediately known in its host, individuals are often infected for some time before a test or immune deficiency symptoms (which leads to a test) identifies them as such.  Regular identification of individuals infected by the virus could have significant public health impacts if knowledge of the infection positively affected sexual behaviors.  This model explores this possibility by making all individuals who know of their positive HIV status always practice safe sex.  


HOW TO USE IT
-------------
The model uses "couples" to represent two people engaged in sexual relations.  Individuals wander about the screen when they are not in couples.  Upon coming into contact with a suitable partner, there is a chance the two individuals will "couple" together.  When this happens, the two individuals no longer move about, they stand next to each other holding hands as a representation of two people in a sexual relationship.  

The presence of the virus in the population is represented by the colors of individuals.  Three colors are used: green individuals are uninfected, blue individuals are infected but their infection is unknown, and red individuals are infected and their infection is known.

A button SETUP creates individuals with particular behavioral tendencies according to the values of the interface's five sliders (described below).  Once the simulation has been setup, you are now ready to run it, by pushing the GO button.  GO starts the simulation and runs it continuously until GO is pushed again.  During a simulation initiated by GO, adjustments in sliders can affect the behavioral tendencies of the population.   

The model's interface window also contains two monitors.  The first monitor shows the percent of the population that is infected by HIV.  The second monitor shows how much time has transpired during the running of the model.  In this model each time-step is considered one week.

Here is a summary of the sliders in the model.  They are explained in more detail below.

  INITIAL-PEOPLE             How many people simulation begins with.
  AVERAGE-COUPLING-TENDENCY  General likelihood member of population has sex (0-10).
  AVERAGE-COMMITMENT         How many weeks sexual relationships typically lasts (0-200).
  AVERAGE-CONDOM-USE         General chance member of population uses a condom. (0-10).
  AVERAGE-TEST-FREQUENCY     Average frequency member of population will check their 
                             HIV status in a 1-year time period (0-2).

The total number of individuals in the simulation is controlled by the slider INITIAL-PEOPLE (initialized to vary between 50 - 500), which must be set before SETUP is pushed.  

During the model's setup procedures, all individuals are given "tendencies" according to four additional sliders.  These tendencies are generally assigned in a normal distribution, so that, for instance, if a tendency slider is set at 8, the most common value for that tendency in the population will be 8.  Less frequently, individuals will have values 7 or 9 for that tendency, and even less frequently will individuals have values 6 or 10 (and so on).
 
The slider AVERAGE-COUPLING-TENDENCY (0 - 10) determines the tendency of the individuals to become involved in couples (as stated earlier, all couples are presumed to be sexually active). When the AVERAGE-COUPLING-TENDENCY slider is set at zero, coupling is unlikely, although (because tendencies are assigned in a normal distribution) it is still possible.  Note that when deciding to couple, both individuals involved must be "willing" to do so, so high coupling tendencies in two individuals are actually compounded (i.e. two individuals with a 50% chance of coupling actually only have a 25% of coupling in a given tick). 

The slider AVERAGE-COMMITMENT (1 - 200) determines how long individuals are likely to stay in a couple (in weeks).  Again, the tendencies of both individuals in a relationship are considered; the relationship only lasts as long as is allowed by the tendency of the partner with a shorter commitment tendency.

The slider AVERAGE-CONDOM-USE (0 - 10) determines the tendency of individuals in the population to practice safe sex.  If an individual uses a condom, it is assumed in this model that no infection by HIV is possible.  Note that this tendency (like the others) is probabilistic at several levels.  For instance, when AVERAGE-CONDOM-USE is set to 9, most of the individuals have a CONDOM-USE value of 9, although some have CONDOM-USE values of 8 or 10, and fewer yet have CONDOM-USE values of 7 or 11 (11 would be off-scale and the same as 10 for all practical purposes).  Also, an individual with a CONDOM-USE value of 9 will still sometimes not choose to use a condom (10% of the time, roughly). Simulation of condom-use is further complicated by the fact that if one partner "wants" to use a condom while the other partner does not, the couple does not use condoms.  This characteristic of the model is representative of the dynamics of some sexual relations, but not others.  The decision was somewhat arbitrary, and the user is invited to play with this characteristic and others in the "Extending the Model" section of this tab. 

The slider AVERAGE-TEST-FREQUENCY (0 - 2) is the final slider of the interface.  It determines the average frequency of an individual to get tested for HIV in a one-year time span.  Set at 1.0, the average person will get tested for HIV about once a year.  Set at 0.2, the average individual will only get tested about every five years.  This tendency has significant impact because the model assumes that individuals who know that they are infected always practice safe sex, even if their tendency as healthy individuals was different.  Again, this characteristic of the model is only represented of the behaviors of some individuals.  The model was designed in this way to highlight the public health effects associated with frequent testing *and* appropriate responses to knowledge of one's HIV status.  To explore the impact of alternative behaviors on public health, the model code can be changed relatively painlessly.  These changes are described in the section, "Extending the Model." 

The model's plot draws a line graph showing the total number of uninfected individuals (green), infected individuals whose positive status is not known (blue), and infected individuals whose positive status is known (red).


THINGS TO NOTICE
----------------
Set the INITIAL-PEOPLE slider to 300, AVERAGE-COUPLING-TENDENCY to 10, AVERAGE-COMMITMENT to 100, and the other two sliders to 0. Push SETUP and then push GO.  Notice that many individuals rapidly pair up into stationary "couples", with the patches behind them stamped a dark gray.  These couples represent sexual activity between the two individuals.  Individuals that continue to move about (and do not have a gray patch behind them) are not engaging in sexual relations.  With RELATIONSHIP-DURATION set to 100, an average individual will have monogamous sexual relations with a partner for about 100 weeks (approximately 2 years) before ending the sexual relationship and searching out a new partner. 

Stop the simulation (by pressing the GO button once again), move the AVERAGE-COUPLING-TENDENCY slider to 0, push SETUP, and start the simulation again (with the GO button).  Notice that this time, couples are not forming.  With a low COUPLING-TENDENCY, individuals do not choose to have sex, which in this model is depicted by the graphical representation of couplehood.  Notice that with these settings, HIV does not typically spread. However, spreading could happen since the population's tendency is set according to a normal distribution and a few people will probably have COUPLING-TENDENCY values above 0 at this setting. 

Again reset the simulation, this time with AVERAGE-COUPLING-TENDENCY set back to 10 and AVERAGE-COMMITMENT set to 1.  Notice that while individuals do not stand still next to each other for any noticeable length of time, coupling is nevertheless occurring.  This is indicated by the occasional flash of dark gray behind individuals that are briefly next to one another.  Notice that the spread of HIV is actually faster when RELATIONSHIP-DURATION is very short compared to when it is very long.

Now run a simulation with AVERAGE-COMMITMENT equal to 1, AVERAGE-COUPLING-TENDENCY set to 1, AVERAGE-CONDOM-USE set to 10, and AVERAGE-TEST-FREQUENCY set to 1.0. With negligible couple formation and high condom use anyway, there should be no spread of HIV.  Notice how pale blue "infection unknown" individuals turn red much quicker in this simulation.  When the individuals turn red, they know their HIV status.  Some individuals turn red because they have been infected for long enough that they develop symptoms, which alerts them to the need for an HIV test.  Others become red because they choose to be tested.  With AVERAGE-TEST-FREQUENCY set to 1.0, healthy individuals are also being tested, but their color does not change since the tests come back negative.  

When all the individuals in the simulation are either green or red, change the sliders without stopping the simulation.  Set AVERAGE-COUPLING-TENDENCY to 10, AVERAGE-COMMITMENT to 100, AVERAGE-CONDOM-USE to 0, and AVERAGE-TEST-FREQUENCY to 0.  Notice that despite the immediate formation of couples and the fact that condom-use tendency is presumably very low, some between healthy (green) individuals and infected (red) individuals, no spread of HIV occurs.  This is because while the model expects HIV positive individuals to continue to engage in sexual relations, it presumes that those individuals will always use condoms and that the condoms will always work.  The rationale for this design is discussed briefly in the "What is it?" section of this tab.

Finally, set INITIAL-PEOPLE to 500 to notice that couples can form on top of each other.  Watch the simulation until you see individuals by themselves, but standing still and with a gray patch behind them indicating coupling.  Underneath one of its neighbors, is the individuals partner.  This apparent bug in the program is necessary because individuals need to be able to couple fairly freely.  If space constraints prohibited coupling, unwanted emergent behavior would occur with high population densities.  

Couples are formed by a partnership of "righty" and "lefty" shapes which is not immediately noticeable.  These shapes are not intended to represent genders in any fashion, but merely to provide a useful way to depict couple graphics. In order for the hands of a righty and lefty to match up, both must be off-centered in their patch.  Without this feature, two couples next to each other would appear to be a line of four individuals (instead of two groups of two).  It is intended that the differences between righty and lefty shapes not be especially apparent in order to prevent unintended associations with gender.  Any righty or lefty shape can be thought of as male or female or neither.


THINGS TO TRY
-------------
Run a number of experiments with the GO button to find out the effects of different variables on the spread of HIV.  Try using good controls in your experiment.  Good controls are when only one variable is changed between trials.  For instance, to find out what effect the average duration of a relationship has, run four experiments with the AVERAGE-COMMITMENT slider set at 1 the first time, 2 the second time, 10 the third time, and 50 the last.  How much does the prevalence of HIV increase in each case?  Does this match your expectations?  

Are the effects of some slider variables mediated by the effects of others?  For instance, if lower AVERAGE-COMMITMENT values seem to increase the spread of HIV when all other sliders are set at 0, does the same thing occur if all other sliders are set at 10?  You can run many experiments to test different hypotheses regarding the emergent public health effects associated with individual sexual behaviors.


EXTENDING THE MODEL
-------------------
Like all computer simulations of human behaviors, this model has necessarily simplified its subject area substantially.  The model therefore provides numerous opportunities for extension: 

The model depicts sexual activity on-screen as two people standing next to each other.  This suggests that all couples have sex and that abstinence is only practiced in singlehood.  The model could be changed to reflect a more realistic view of what couples are.  Individuals could be in couples without having sex.  To show sex, then, a new graphical representation would have to be employed.  Perhaps sex could be symbolized by having the patches beneath the couple flash briefly to a different color.

The model does not distinguish between genders.  This is an obvious over-simplification chosen because making an exclusively heterosexual model was untenable while making one that included a variety of sexual preferences might have distracted from the public health issues which it was designed to explore.  However, extending the model by adding genders would make the model more realistic.

The model assumes that individuals who are aware that they are infected always practice safe sex.  This portrayal of human behavior is clearly not entirely realistic, but it does create interesting emergent behavior that has genuine relevance to certain public health debate.  However, an interesting extension of the model would be to change individuals' reactions to knowledge of HIV status.

The model assumes that condom use is always 100% effective.  In fact, responsible condom use is actually slightly less than ideal protection from the transmission of HIV.  Add a line of code to the INFECT procedure to check for a slight random chance that a particular episode of condom-use is not effective.  Another change that can be made in the INFECT procedure regards a couple's choice of condom-use.  In this model, when the two partners of a couple "disagree" about whether or not to use a condom, the partner that doesn't wish to use a condom makes the choice.  The opposite possibility is also valid. 

Finally, certain significant changes can easily be made in the model by simply changing the value of certain global variables in the procedure SETUP-GLOBALS.  Two variables set in this procedure that are especially worthy of investigation are INFECTION-CHANCE and SYMPTOMS-SHOW.  The former controls what chance an infection has of spreading from an infected to an uninfected partner if no protection is used.  The variable is currently set to 50, meaning that in a week of sexual relations, the chance of infection occurring is 50%.  It is not clear at this time how realistic that figure is.  SYMPTOMS-SHOW is the variable that controls how long, on average, a person will have the HIV virus before symptoms begin to appear, alerting that person to the presence of some health problem.  It is currently set to 200 (weeks) in this model. 


NETLOGO FEATURES
-----------------
Notice that the four procedures that assign the different tendencies generate many small random numbers and add them together.  This produces a normal distribution of tendency values.  A random number between 0 and 100 is as likely to be 1 as it is to be 99. However, the sum of 20 numbers between 0 and 5 is much more likely to be 50 than it is to be 99.

Notice that the global variables SLIDER-CHECK-1, SLIDER-CHECK-2, and so on are assigned with the values of the various sliders so that the model can check the sliders against the variables while the model is running.  Every time-step, a slider's value is checked against a global variable that holds the value of what the slider's value was the time-step before.  If the slider's current value is different than the global variable, NetLogo knows to call procedures that adjust the population's tendencies.  Otherwise, those adjustment procedures are not called.


CREDITS AND REFERENCES
----------------------
Special thanks to Steve Longenecker for model development.

To refer to this model in academic publications, please use: Wilensky, U. (1998).  NetLogo AIDS model. http://ccl.northwestern.edu/netlogo/models/AIDS. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use: Copyright 1998 by Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/AIDS for terms of use.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

healthy-person
false
15
Circle -11352576 true false 108 3 80
Rectangle -11352576 true false 89 76 209 205
Polygon -11352576 true false 89 75 23 139 26 151 54 151 99 100
Polygon -11352576 true false 207 75 275 137 275 150 245 150 200 99
Polygon -11352576 true false 148 204 118 298 74 298 108 205
Polygon -11352576 true false 155 204 172 298 211 298 190 203

lefty
false
0
Circle -7566196 true true 135 0 92
Rectangle -7566196 true true 173 91 193 105
Rectangle -7566196 true true 144 99 218 226
Polygon -7566196 true true 217 100 296 150 296 182 207 145
Polygon -7566196 true true 217 226 231 296 195 296 195 213
Polygon -7566196 true true 145 223 127 295 166 295 166 204
Polygon -7566196 true true 145 99 64 150 64 180 146 148
Rectangle -7566196 true true 167 88 194 103

righty
false
0
Circle -7566196 true true 74 0 91
Rectangle -7566196 true true 105 86 135 121
Rectangle -7566196 true true 82 96 158 225
Polygon -7566196 true true 82 97 1 150 1 180 87 147
Polygon -7566196 true true 157 96 237 149 237 178 150 148
Polygon -7566196 true true 84 223 67 293 110 293 110 213
Polygon -7566196 true true 156 224 176 294 128 294 128 216

std-known-person
false
15
Circle -11352576 true false 108 3 80
Rectangle -11352576 true false 89 76 209 205
Polygon -11352576 true false 89 75 23 139 26 151 54 151 99 100
Polygon -11352576 true false 207 75 275 137 275 150 245 150 200 99
Polygon -11352576 true false 148 204 118 298 74 298 108 205
Polygon -11352576 true false 155 204 172 298 211 298 190 203
Rectangle -65536 true false 90 74 208 204
Circle -65536 true false 103 -4 88
Polygon -65536 true false 147 200 120 293 117 298 71 298 108 201
Polygon -65536 true false 153 200 170 299 214 299 189 197
Polygon -65536 true false 90 73 22 138 24 150 57 150 91 109
Polygon -65536 true false 205 73 275 136 275 150 243 150 204 109

std-unknown-person
false
15
Circle -11352576 true false 108 3 80
Rectangle -11352576 true false 89 76 209 205
Polygon -11352576 true false 89 75 23 139 26 151 54 151 99 100
Polygon -11352576 true false 207 75 275 137 275 150 245 150 200 99
Polygon -11352576 true false 148 204 118 298 74 298 108 205
Polygon -11352576 true false 155 204 172 298 211 298 190 203
Rectangle -16776961 true false 89 74 209 205
Circle -16776961 true false 106 -1 82
Polygon -16776961 true false 147 201 118 297 72 297 109 201
Polygon -16776961 true false 154 202 172 299 212 299 187 194 154 202
Polygon -16776961 true false 88 74 20 141 27 152 54 152 95 105
Polygon -16776961 true false 207 74 274 136 275 151 242 151 207 106

@#$#@#$#@
NetLogo 2.0beta5
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@